Missing .sublime-syntax for Yacc/Bison highlighting

[malikwirin]

Hi everyone,

I'm trying to set up syntax highlighting for Yacc/Bison files (.y, .yacc) in bat via Nix Home Manager.

I realized that bat requires modern .sublime-syntax files and doesn't support the older .tmLanguage format directly anymore. While there are plenty of TextMate bundles for Bison out there, I haven't been able to find a working .sublime-syntax definition in the usual places (Sublime Packages repo, bat default assets).

Does anyone here have a working .sublime-syntax file for Yacc/Bison they could share, or point me to a repository that maintains one?

Thanks in advance!

[keith-hall]

Hi, maybe https://codeberg.org/ISSOtm/sublime-Bison

[malikwirin]

Wow thank you very much, works great!

[malikwirin]

I packaged it has Nix Derivation like this:

{
  lib,
  stdenv,
  fetchFromGitea,
}:

stdenv.mkDerivation rec {
  pname = "sublime-bison";
  version = "2.1.0";

  src = fetchFromGitea {
    domain = "codeberg.org";
    owner = "ISSOtm";
    repo = "sublime-Bison";
    rev = version;
    hash = "sha256-hOioRUeaSXaCjDoamIeZzeVdoxAJv/WN/1ojTY7N9OU=";
  };

  installPhase = ''
    mkdir -p $out/Completions
    cp Completions/*.sublime-completions $out/Completions
    cp *.sublime-syntax* $out
  '';

  meta = {
    description = "A Sublime Text syntax definition for Bison grammar files";
    homepage = "https://codeberg.org/ISSOtm/sublime-Bison";
    license = lib.licenses.mit;
    maintainers = with lib.maintainers; [ malik ];
    mainProgram = "sublime-bison";
    platforms = lib.platforms.all;
  };
}

My Bat Nix-Home-Manager Configuration uses it like this:

programs.bat = {
      enable = true;

      config = {
        map-syntax = [
          "*.tpp:C++"
          # Bison (C)
          "*.y:Bison"
          "*.yacc:Bison"
          "*.bison:Bison"
          # Bison (C++)
          "*.yy:Bison (C++)"
          "*.ypp:Bison (C++)"
          "*.yxx:Bison (C++)"
          "*.y++:Bison (C++)"
        ];
      };

      syntaxes = {
        dhall = {
          src = pkgs.syntax-files.dhall.sublime;
          file = "dhall.sublime-syntax";
        };
        bison = {
          src = pkgs.syntax-files.bison.sublime;
          file = "Bison.sublime-syntax";
        };
        bison-cpp = {
          src = pkgs.syntax-files.bison.sublime;
          file = "Bison++.sublime-syntax";
        };
      };
    };