Using Groovy @SourceURI with Picocli @PicocliScript2 and Subcommands???

[mattbertolini]

I'm writing a Groovy script with Picocli and the PicocliScript2 annotation. So far everything is working great! I want to get the script's location and I know that Groovy has an annotation @SourceURI to do just that. When I try to use it in conjunction with Picocli and method subcommands, it doesn't work. The URI is printed in the standard script path but throws an exception when I try to access it in the subcommand method. Here's an example script that demonstrates it:

@Grab('info.picocli:picocli-groovy:4.7.7')
@GrabConfig(systemClassLoader = true)
@picocli.CommandLine.Command(name = "example", mixinStandardHelpOptions = true, description = "Example script")
@picocli.groovy.PicocliScript2
import groovy.transform.Field
import groovy.transform.SourceURI
import picocli.CommandLine.Command
import picocli.CommandLine.ExitCode
import picocli.CommandLine.Help.Ansi
import picocli.CommandLine.Model.CommandSpec
import picocli.CommandLine.Spec

@SourceURI
URI scriptSourceUri

@Field
@Spec
CommandSpec spec

println(scriptSourceUri) // This prints the URI

println(Ansi.AUTO.text('@|bold,red ERROR|@ Missing command'))
spec.commandLine().usage(System.err)
System.exit(ExitCode.USAGE)

@SuppressWarnings('unused')
@Command(name = "start", description = "Start")
int startCluster() {
    println(scriptSourceUri) // groovy.lang.MissingPropertyException: No such property: scriptSourceUri for class: example
    return ExitCode.OK
}

@SuppressWarnings('unused')
@Command(name = "delete", description = "Delete")
int deleteCluster() {
    println(scriptSourceUri) // No such property: scriptSourceUri for class: example
    return ExitCode.OK
}

Here's the exception that I get:

Caught: groovy.lang.GroovyRuntimeException
groovy.lang.GroovyRuntimeException
	at picocli.groovy.PicocliBaseScript2.afterExecution(PicocliBaseScript2.java:188)
	at picocli.groovy.PicocliBaseScript2.run(PicocliBaseScript2.java:161)
Caused by: groovy.lang.MissingPropertyException: No such property: scriptSourceUri for class: example
	at example.deleteCluster(example.groovy:42)
	at picocli.CommandLine.executeUserObject(CommandLine.java:2070)
	at picocli.CommandLine.access$1500(CommandLine.java:148)
	at picocli.CommandLine$RunLast.executeUserObjectOfLastSubcommandWithSameParent(CommandLine.java:2469)
	at picocli.CommandLine$RunLast.handle(CommandLine.java:2461)
	at picocli.CommandLine$RunLast.handle(CommandLine.java:2423)
	at picocli.CommandLine$AbstractParseResultHandler.execute(CommandLine.java:2277)
	at picocli.CommandLine$RunLast.execute(CommandLine.java:2425)
	at picocli.CommandLine.execute(CommandLine.java:2174)
	at picocli.groovy.PicocliBaseScript2.run(PicocliBaseScript2.java:160)

I'm aware that both @SourceURI and @PicocliScript2 do AST transformation. I'm wondering if they are conflicting with each other. Is it possible to use the @SourceURI in conjunction with subcommands? If so, how do I manage this? Thanks!

[remkop]

Hi that's a good question. I suspect you may be right about the AST transformations...
My knowledge in that area is very limited.
Could you ask this question on the Groovy user mailing list? There are more knowledgeable experts there that may be able to help.

[mattbertolini]

I appreciate you taking a look! I just stumbled upon a fix and while It's not the best it's definitely something!

I originally thought I should mark the annotated @SourceURI variable with @Field as well to add it to the class that Picocli was creating. This works great with the other variables in the script.

@Field
@SourceURI
URI scriptSourceUri

When I did this it didn't work. I can't remember if the variable was null or if there was an exception but I abandoned it. I just reversed the order of the annotations and it worked!

@SourceURI
@Field
URI scriptSourceUri

I'm not thrilled that the order matters here but I'm just glad it works!

I will definitely reach out to the groovy folks to find out why the order matters when dealing with AST transformation. Thanks again for taking a look!