fontconfig: workaround KDE overwriting symlink

modules/misc/fontconfig.nix

@@ -196,6 +196,26 @@ in
 
       };
 
+      mutablePlaceholder = lib.mkOption {
+        default = { };
+        description = ''
+          This can be required for Desktop Environments that will otherwise overwrite symlinks managed by home-manager.
+          For example, [KDE](https://bugs.kde.org/show_bug.cgi?id=498694).'';
+
+        type = lib.types.submodule {
+          options = {
+            enable = lib.mkEnableOption "a mutable placeholder config file";
+
+            file = lib.mkOption {
+              type = lib.types.str;
+              default = "${config.xdg.configHome}/fontconfig/conf.d/00-aaa-mutable.conf";
+              internal = true;
+              readOnly = true;
+              description = "The mutable placeholder file to create.";
+            };
+          };
+        };
+      };
     };
   };
 
@@ -343,5 +363,9 @@ in
         source = lib.mkIf (config.source != null) config.source;
       }
     ) cfg.configFile;
+
+    systemd.user.tmpfiles.rules = lib.mkIf cfg.mutablePlaceholder.enable [
+      "f ${cfg.mutablePlaceholder.file} - - - -"
+    ];
   };
 }

tests/modules/misc/fontconfig/default.nix

@@ -1,3 +1,4 @@
+{ lib, pkgs, ... }:
 {
   fontconfig-no-font-package = ./no-font-package.nix;
   fontconfig-single-font-package = ./single-font-package.nix;
@@ -24,3 +25,6 @@
   fontconfig-custom-rendering = ./custom-rendering.nix;
   fontconfig-extra-config-files = ./extra-config-files.nix;
 }
+// lib.optionalAttrs pkgs.stdenv.hostPlatform.isLinux {
+  fontconfig-mutable-placeholder = ./mutable-placeholder.nix;
+}

tests/modules/misc/fontconfig/mutable-placeholder.nix

@@ -0,0 +1,23 @@
+{ config, realPkgs, ... }:
+let
+  cfg = config.fonts.fontconfig.mutablePlaceholder;
+in
+{
+  fonts.fontconfig.enable = true;
+  fonts.fontconfig.mutablePlaceholder.enable = true;
+
+  nmt.script = ''
+    SYSTEMD_LOG_LEVEL=debug ${realPkgs.systemd}/bin/systemd-tmpfiles \
+      -E \
+      --root "$TEMPDIR/chroot" \
+      --create \
+      --remove \
+      --boot \
+      "$TESTED/home-files/.config/user-tmpfiles.d/home-manager.conf"
+
+    assertFileExists "$TEMPDIR/chroot/${cfg.file}"
+    assertFileNotRegex "$TEMPDIR/chroot/${cfg.file}" .
+  '';
+
+  test.stubs.systemd.outPath = null;
+}