adding seqkit grep (#3500)

* adding seqkit grep

* removing todo

* Implementing suggestions and test

* Fixing tests

Author: Joon-Klaps

modules/nf-core/seqkit/grep/main.nf

@@ -0,0 +1,58 @@
+process SEQKIT_GREP {
+    tag "$meta.id"
+    label 'process_low'
+
+
+    conda "bioconda::seqkit=2.4.0"
+    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
+        'https://depot.galaxyproject.org/singularity/seqkit:2.4.0--h9ee0642_0':
+        'biocontainers/seqkit:2.4.0--h9ee0642_0' }"
+
+    input:
+    tuple val(meta), path(sequence)
+    path pattern
+
+    output:
+    tuple val(meta), path("*.{fa,fq}.gz")  , emit: filter
+    path "versions.yml"                    , emit: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    // fasta or fastq. Exact pattern match .fasta or .fa suffix with optional .gz (gzip) suffix
+    def suffix = task.ext.suffix ?: "${sequence}" ==~ /(.*f[astn]*a(.gz)?$)/ ? "fa" : "fq"
+    def pattern_file = pattern ? "-f ${pattern}" : ""
+
+    """
+    seqkit \\
+        grep \\
+        $args \\
+        --threads $task.cpus \\
+        ${pattern_file} \\
+        ${sequence} \\
+        -o ${prefix}.${suffix}.gz \\
+
+    cat <<-END_VERSIONS > versions.yml
+    "${task.process}":
+        seqkit: \$( seqkit version | sed 's/seqkit v//' )
+    END_VERSIONS
+    """
+
+    stub:
+    def args = task.ext.args ?: ''
+    def prefix = task.ext.prefix ?: "${meta.id}"
+    // fasta or fastq. Exact pattern match .fasta or .fa suffix with optional .gz (gzip) suffix
+    def suffix = task.ext.suffix ?: "${sequence}" ==~ /(.*f[astn]*a(.gz)?$)/ ? "fa" : "fq"
+
+    """
+    touch ${prefix}.${suffix}.gz
+
+    cat <<-END_VERSIONS > versions.yml
+    "${task.process}":
+        seqkit: \$( seqkit version | sed 's/seqkit v//' )
+    END_VERSIONS
+    """
+}

modules/nf-core/seqkit/grep/meta.yml

@@ -0,0 +1,57 @@
+---
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/modules/yaml-schema.json
+name: "seqkit_grep"
+description: Select sequences from a large file based on name/ID
+keywords:
+  - filter
+  - seqkit
+  - subseq
+  - grep
+tools:
+  - "seqkit":
+      description: Cross-platform and ultrafast toolkit for FASTA/Q file manipulation, written by Wei Shen.
+      homepage: https://bioinf.shenwei.me/seqkit/usage/
+      documentation: https://bioinf.shenwei.me/seqkit/usage/
+      tool_dev_url: https://github.com/shenwei356/seqkit/
+      doi: "10.1371/journal.pone.0163962"
+      licence: ["MIT"]
+
+input:
+  - meta:
+      type: map
+      description: >
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+
+  - sequence:
+      type: file
+      description: >
+        Fasta or fastq file containing sequences to be filtered
+      pattern: "*.{fa,fna,faa,fasta,fq,fastq}[.gz]"
+
+  - pattern:
+      type: file
+      description: >
+        pattern file (one record per line). If no pattern is given, a string can be specificied within the args using '-p pattern_string'
+      pattern: "*.{txt,tsv}"
+
+output:
+  - meta:
+      type: map
+      description: >
+        Groovy Map containing sample information
+        e.g. [ id:'test', single_end:false ]
+
+  - versions:
+      type: file
+      description: File containing software versions
+      pattern: "versions.yml"
+
+  - filter:
+      type: file
+      description: >
+        Fasta or fastq file containing the filtered sequences
+      pattern: "*.{fa,fq}[.gz]"
+
+authors:
+  - "@Joon-Klaps"

tests/config/pytest_modules.yml

@@ -3139,6 +3139,10 @@ sentieon/varcal:
   - modules/nf-core/sentieon/varcal/**
   - tests/modules/nf-core/sentieon/varcal/**
 
+seqkit/grep:
+  - modules/nf-core/seqkit/grep/**
+  - tests/modules/nf-core/seqkit/grep/**
+
 seqkit/pair:
   - modules/nf-core/seqkit/pair/**
   - tests/modules/nf-core/seqkit/pair/**

tests/modules/nf-core/seqkit/grep/main.nf

@@ -0,0 +1,32 @@
+#!/usr/bin/env nextflow
+
+nextflow.enable.dsl = 2
+
+include { SEQKIT_GREP as SEQKIT_GREP_FILE    } from '../../../../../modules/nf-core/seqkit/grep/main.nf'
+include { SEQKIT_GREP as SEQKIT_GREP_STRING  } from '../../../../../modules/nf-core/seqkit/grep/main.nf'
+
+workflow test_seqkit_grep_file {
+
+    sequence = [
+        [ id:'test', single_end:false ], // meta map
+        file(params.test_data['homo_sapiens']['genome']['genome_21_fasta'], checkIfExists: true)
+    ]
+
+    pattern = [
+        file(params.test_data['homo_sapiens']['genome']['genome_header'], checkIfExists: true)
+    ]
+
+    SEQKIT_GREP_FILE ( sequence, pattern )
+}
+
+workflow test_seqkit_grep_string {
+
+    sequence = [
+        [ id:'test', single_end:false ], // meta map
+        file(params.test_data['homo_sapiens']['genome']['genome_fasta_gz'], checkIfExists: true)
+    ]
+
+    pattern = []
+
+    SEQKIT_GREP_STRING ( sequence, pattern)
+}

tests/modules/nf-core/seqkit/grep/nextflow.config

@@ -0,0 +1,10 @@
+process {
+
+    publishDir = { "${params.outdir}/${task.process.tokenize(':')[-1].tokenize('_')[0].toLowerCase()}" }
+
+    withName: SEQKIT_GREP_STRING {
+        ext.args = "-p chr22"
+    }
+
+    
+}

tests/modules/nf-core/seqkit/grep/test.yml

@@ -0,0 +1,19 @@
+- name: seqkit grep test_seqkit_grep_file
+  command: nextflow run ./tests/modules/nf-core/seqkit/grep -entry test_seqkit_grep_file -c ./tests/config/nextflow.config -c ./tests/modules/nf-core/seqkit/grep/nextflow.config
+  tags:
+    - seqkit
+    - seqkit/grep
+  files:
+    - path: output/seqkit/test.fa.gz
+      md5sum: d2c774388d0cffb4663a2c4b5b6dd5df
+    - path: output/seqkit/versions.yml
+
+- name: seqkit grep test_seqkit_grep_string
+  command: nextflow run ./tests/modules/nf-core/seqkit/grep -entry test_seqkit_grep_string -c ./tests/config/nextflow.config -c ./tests/modules/nf-core/seqkit/grep/nextflow.config
+  tags:
+    - seqkit
+    - seqkit/grep
+  files:
+    - path: output/seqkit/test.fa.gz
+      md5sum: 9179d23d51c48c03c0f68479440db36c
+    - path: output/seqkit/versions.yml