[E-Documents Core] - Migrate electronic formats to new purchase draft concept for e-invoicing (e-invoice preview) (PEPPOL)

Apps/W1/EDocument/app/src/Document/EDocument.Table.al

@@ -479,6 +479,7 @@ table 6121 "E-Document"
         exit(GetEDocumentServiceStatus()."Import Processing Status");
     end;
 #endif
+
     internal procedure ToString(): Text
     begin
         exit(StrSubstNo(ToStringLbl, SystemId, "Document Record ID", "Workflow Step Instance ID", "Job Queue Entry ID"));

Apps/W1/EDocument/app/src/Document/EDocumentType.Enum.al

@@ -56,6 +56,7 @@ enum 6121 "E-Document Type" implements IEDocumentFinishDraft
     value(10; "Purchase Credit Memo")
     {
         Caption = 'Purchase Credit Memo';
+        Implementation = IEDocumentFinishDraft = "E-Doc. Create Purch. Cr. Memo";
     }
     value(11; "Service Order")
     {

Apps/W1/EDocument/app/src/Helpers/EDocumentXMLHelper.Codeunit.al

@@ -0,0 +1,126 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.eServices.EDocument.Helpers;
+
+using Microsoft.Finance.GeneralLedger.Setup;
+
+codeunit 6177 "EDocument XML Helper"
+{
+    Access = Internal;
+
+    /// <summary>
+    /// Extracts currency value from XML document and sets it in the currency field if it differs from LCY.
+    /// </summary>
+    /// <param name="XMLDocument">The XML document to search in.</param>
+    /// <param name="XMLNamespaces">The XML namespace manager for XPath queries.</param>
+    /// <param name="Path">The XPath expression to locate the currency value.</param>
+    /// <param name="MaxLength">The maximum length of the currency code.</param>
+    /// <param name="CurrencyField">The currency field to update with the extracted value.</param>
+    internal procedure SetCurrencyValueInField(XMLDocument: XmlDocument; XMLNamespaces: XmlNamespaceManager; Path: Text; MaxLength: Integer; var CurrencyField: Code[10])
+    var
+        GLSetup: Record "General Ledger Setup";
+        XMLNode: XmlNode;
+        CurrencyCode: Code[10];
+    begin
+        if not XMLDocument.SelectSingleNode(Path, XMLNamespaces, XMLNode) then
+            exit;
+
+        GLSetup.Get();
+
+#pragma warning disable AA0139 // false positive
+        if XMLNode.IsXmlElement() then begin
+            CurrencyCode := CopyStr(XMLNode.AsXmlElement().InnerText(), 1, MaxLength);
+            if GLSetup."LCY Code" <> CurrencyCode then
+                CurrencyField := CurrencyCode;
+            exit;
+        end;
+
+        if XMLNode.IsXmlAttribute() then begin
+            CurrencyCode := CopyStr(XMLNode.AsXmlAttribute().Value, 1, MaxLength);
+            if GLSetup."LCY Code" <> CurrencyCode then
+                CurrencyField := CurrencyCode;
+            exit;
+        end;
+#pragma warning restore AA0139
+    end;
+
+    /// <summary>
+    /// Extracts string value from XML document and sets it in the specified field.
+    /// </summary>
+    /// <param name="XMLDocument">The XML document to search in.</param>
+    /// <param name="XMLNamespaces">The XML namespace manager for XPath queries.</param>
+    /// <param name="Path">The XPath expression to locate the string value.</param>
+    /// <param name="MaxLength">The maximum length of the string value.</param>
+    /// <param name="Field">The text field to update with the extracted value.</param>
+    internal procedure SetStringValueInField(XMLDocument: XmlDocument; XMLNamespaces: XmlNamespaceManager; Path: Text; MaxLength: Integer; var Field: Text)
+    var
+        XMLNode: XmlNode;
+    begin
+        if not XMLDocument.SelectSingleNode(Path, XMLNamespaces, XMLNode) then
+            exit;
+
+        if XMLNode.IsXmlElement() then begin
+            Field := CopyStr(XMLNode.AsXmlElement().InnerText(), 1, MaxLength);
+            exit;
+        end;
+
+        if XMLNode.IsXmlAttribute() then begin
+            Field := CopyStr(XMLNode.AsXmlAttribute().Value(), 1, MaxLength);
+            exit;
+        end;
+    end;
+
+    /// <summary>
+    /// Extracts numeric value from XML document and sets it in the specified decimal field.
+    /// </summary>
+    /// <param name="XMLDocument">The XML document to search in.</param>
+    /// <param name="XMLNamespaces">The XML namespace manager for XPath queries.</param>
+    /// <param name="Path">The XPath expression to locate the numeric value.</param>
+    /// <param name="DecimalValue">The decimal field to update with the extracted value.</param>
+    internal procedure SetNumberValueInField(XMLDocument: XmlDocument; XMLNamespaces: XmlNamespaceManager; Path: Text; var DecimalValue: Decimal)
+    var
+        XMLNode: XmlNode;
+    begin
+        if not XMLDocument.SelectSingleNode(Path, XMLNamespaces, XMLNode) then
+            exit;
+
+        if XMLNode.AsXmlElement().InnerText() <> '' then
+            Evaluate(DecimalValue, XMLNode.AsXmlElement().InnerText(), 9);
+    end;
+
+    /// <summary>
+    /// Extracts date value from XML document and sets it in the specified date field.
+    /// </summary>
+    /// <param name="XMLDocument">The XML document to search in.</param>
+    /// <param name="XMLNamespaces">The XML namespace manager for XPath queries.</param>
+    /// <param name="Path">The XPath expression to locate the date value.</param>
+    /// <param name="DateValue">The date field to update with the extracted value.</param>
+    internal procedure SetDateValueInField(XMLDocument: XmlDocument; XMLNamespaces: XmlNamespaceManager; Path: Text; var DateValue: Date)
+    var
+        XMLNode: XmlNode;
+    begin
+        if not XMLDocument.SelectSingleNode(Path, XMLNamespaces, XMLNode) then
+            exit;
+
+        if XMLNode.AsXmlElement().InnerText() <> '' then
+            Evaluate(DateValue, XMLNode.AsXmlElement().InnerText(), 9);
+    end;
+
+    /// <summary>
+    /// Retrieves the inner text value of an XML node using XPath expression.
+    /// </summary>
+    /// <param name="XmlDoc">The XML document to search in.</param>
+    /// <param name="XmlNamespaces">The XML namespace manager for XPath queries.</param>
+    /// <param name="XPath">The XPath expression to locate the node.</param>
+    /// <returns>The inner text value of the found node, or empty string if node not found.</returns>
+    internal procedure GetNodeValue(XmlDoc: XmlDocument; XmlNamespaces: XmlNamespaceManager; XPath: Text): Text
+    var
+        XMLNode: XmlNode;
+    begin
+        if XmlDoc.SelectSingleNode(XPath, XmlNamespaces, XMLNode) then
+            exit(XMLNode.AsXmlElement().InnerText());
+        exit('');
+    end;
+}

Apps/W1/EDocument/app/src/Processing/EDocumentCreatePurchDoc.Codeunit.al

@@ -156,6 +156,10 @@ codeunit 6136 "E-Document Create Purch. Doc."
                             EDocumentImportHelper.ProcessField(EDocument, DocumentLine, PurchaseField, TempDocumentLine.Field(PurchaseField."No."));
                     until PurchaseField.Next() = 0;
 
+                // After processing all fields, set direct unit cost to be the same as in the import file
+                if Format(DocumentLine.Field(PurchaseLine.FieldNo(Type)).Value()) <> '0' then 
+                    EDocumentImportHelper.ProcessDecimalField(EDocument, DocumentLine, PurchaseLine.FieldNo("Direct Unit Cost"), TempDocumentLine.Field(PurchaseLine.FieldNo("Direct Unit Cost")).Value());
+
                 OnCreateNewPurchLineOnBeforeRecRefModify(EDocument, TempDocumentHeader, DocumentHeader, TempDocumentLine, DocumentLine);
                 DocumentLine.Modify(true);
             until TempDocumentLine.Next() = 0;

Apps/W1/EDocument/app/src/Processing/Import/EDocEmptyDraft.Codeunit.al

@@ -50,4 +50,12 @@ codeunit 6193 "E-Doc. Empty Draft" implements IStructureReceivedEDocument, IStru
     begin
         Error(NoDataErr);
     end;
+
+    procedure ResetDraft(EDocument: Record "E-Document")
+    var
+        EDocPurchaseHeader: Record "E-Document Purchase Header";
+    begin
+        EDocPurchaseHeader.GetFromEDocument(EDocument);
+        EDocPurchaseHeader.Delete(true);
+    end;
 }

Apps/W1/EDocument/app/src/Processing/Import/EDocUnspecifiedImpl.Codeunit.al

@@ -61,6 +61,11 @@ codeunit 6116 "E-Doc. Unspecified Impl." implements IStructureReceivedEDocument,
     begin
     end;
 
+    procedure ResetDraft(EDocument: Record "E-Document")
+    begin
+        // No actions to undo
+    end;
+
     var
         EDocumentNoReadSpecifiedErr: Label 'No method to read the e-document has been provided.';
 }

Apps/W1/EDocument/app/src/Processing/Import/FinishDraft/EDocCreatePurchCrMemo.Codeunit.al

@@ -0,0 +1,78 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.eServices.EDocument.Processing.Import;
+
+using Microsoft.eServices.EDocument;
+using Microsoft.eServices.EDocument.Processing.Import.Purchase;
+using Microsoft.eServices.EDocument.Processing.Interfaces;
+using Microsoft.Finance.Dimension;
+using Microsoft.Purchases.Document;
+
+/// <summary>
+/// Dealing with the creation of the purchase credit memo after the draft has been populated.
+/// </summary>
+codeunit 6105 "E-Doc. Create Purch. Cr. Memo" implements IEDocumentFinishDraft, IEDocumentCreatePurchaseCreditMemo
+{
+    Access = Internal;
+    Permissions = tabledata "Dimension Set Tree Node" = im,
+                  tabledata "Dimension Set Entry" = im;
+
+    var
+        EDocImpSessionTelemetry: Codeunit "E-Doc. Imp. Session Telemetry";
+
+    /// <summary>
+    /// Applies the draft E-Document to Business Central by creating a purchase credit memo from the draft data.
+    /// </summary>
+    /// <param name="EDocument">The E-Document record containing the draft data to be applied.</param>
+    /// <param name="EDocImportParameters">The import parameters containing processing customizations.</param>
+    /// <returns>The RecordId of the created purchase credit memo.</returns>
+    internal procedure ApplyDraftToBC(EDocument: Record "E-Document"; EDocImportParameters: Record "E-Doc. Import Parameters"): RecordId
+    var
+        EDocumentPurchaseHeader: Record "E-Document Purchase Header";
+        PurchaseHeader: Record "Purchase Header";
+        EDocPurchaseDocumentHelper: Codeunit "E-Doc Purchase Document Helper";
+        IEDocumentFinishPurchaseDraft: Interface IEDocumentCreatePurchaseCreditMemo;
+    begin
+        EDocumentPurchaseHeader.GetFromEDocument(EDocument);
+        IEDocumentFinishPurchaseDraft := EDocImportParameters."Processing Customizations";
+        PurchaseHeader := IEDocumentFinishPurchaseDraft.CreatePurchaseCreditMemo(EDocument);
+
+        // Post document validation - Silently emit telemetry
+        if not EDocPurchaseDocumentHelper.TryValidateDocumentTotals(PurchaseHeader) then
+            EDocImpSessionTelemetry.SetBool('Totals Validation Failed', true);
+
+        exit(PurchaseHeader.RecordId);
+    end;
+
+    /// <summary>
+    /// Reverts the draft actions by deleting the associated purchase credit memo document.
+    /// </summary>
+    /// <param name="EDocument">The E-Document record whose draft actions should be reverted.</param>
+    internal procedure RevertDraftActions(EDocument: Record "E-Document")
+    var
+        PurchaseHeader: Record "Purchase Header";
+    begin
+        PurchaseHeader.SetRange("E-Document Link", EDocument.SystemId);
+        if not PurchaseHeader.FindFirst() then
+            exit;
+
+        PurchaseHeader.TestField("Document Type", "Purchase Document Type"::"Credit Memo");
+        Clear(PurchaseHeader."E-Document Link");
+        PurchaseHeader.Delete(true);
+    end;
+
+    /// <summary>
+    /// Creates a purchase credit memo from E-Document draft data, including header and line information.
+    /// </summary>
+    /// <param name="EDocument">The E-Document record containing the draft data to create the credit memo from.</param>
+    /// <returns>The created purchase header record for the credit memo.</returns>
+    internal procedure CreatePurchaseCreditMemo(EDocument: Record "E-Document") PurchaseHeader: Record "Purchase Header"
+    var
+        EDocPurchaseDocumentHelper: Codeunit "E-Doc Purchase Document Helper";
+    begin
+        PurchaseHeader := EDocPurchaseDocumentHelper.CreatePurchaseDocumentHeader(EDocument, "Purchase Document Type"::"Credit Memo");
+        exit(PurchaseHeader);
+    end;
+}