transient-setup: Not a transient prefix command or group definition

[rnadler]

The password-menu package has been creating transient menus fine for over a year.
This may not be the best way to dynamically create a transient menu: https://github.com/rnadler/password-menu/blob/main/password-menu.el#L202-L209, but it worked.

Recently -- not sure exactly when -- I started to see this error:

Error during redisplay: (clear-minibuffer-message) signaled (excessive-lisp-nesting 1702)
Not a legacy group definition: password-menu-prefix-list: (excessive-lisp-nesting 1702)
Error during redisplay: (set-message-functions "Not a legacy group definition: password-menu-prefix-list: (excessive-lisp-nesting 1702)") signaled (excessive-lisp-nesting 1702)
Not a legacy group definition: password-menu-prefix-list: (excessive-lisp-nesting 1702)
Error during redisplay: (set-message-functions "Not a legacy group definition: password-menu-prefix-list: (excessive-lisp-nesting 1702)") signaled (error "Lisp nesting exceeds ‘max-lisp-eval-depth’")
Not a legacy group definition: password-menu-prefix-list: (error "Not a transient prefix command or group definition: password-menu-prefix-list") [40 times]
transient-setup: Not a transient prefix command or group definition: password-menu-prefix-list

Debugger output (duplicates removed):

Debugger entered--Lisp error: (error "Lisp nesting exceeds ‘max-lisp-eval-depth’")
transient--exit-and-debug(error (error "Lisp nesting exceeds ‘max-lisp-eval-depth’"))
transient-prefix--eieio-childp(password-menu-prefix-list)
transient-parse-suffix(password-menu-prefix-list ["Get password for: " ("1" "bobn@BOBN-LAPTOP" (lambda nil (interactive) (password-menu-get-password "bobn" "BOBN-LAPTOP"))) ... ])
transient--get-layout(password-menu-prefix-list)
transient-parse-suffix(password-menu-prefix-list ["Get password for: " ("1" "bobn@BOBN-LAPTOP" (lambda nil (interactive) (password-menu-get-password "bobn" "BOBN-LAPTOP"))) ... ])
transient--get-layout(password-menu-prefix-list)
...
transient--get-layout(password-menu-prefix-list)
transient--get-children(password-menu-prefix-list)
transient--init-child(nil password-menu-prefix-list nil)
#f(compiled-function (c) #<bytecode -0x40d6ca8393395bd>)(password-menu-prefix-list)
transient--init-suffixes(password-menu-prefix)
transient--init-objects(password-menu-prefix nil nil)
transient--init-transient(password-menu-prefix nil nil)
#f(compiled-function () #<bytecode -0x1b4fd476928b7fe7>)()
transient--env-apply(#f(compiled-function () #<bytecode -0x1b4fd476928b7fe7>) #)
transient-setup(password-menu-prefix)
password-menu-prefix()
password-menu-transient()
funcall-interactively(password-menu-transient)
command-execute(password-menu-transient)

magit-version:

Magit v4.3.6, Transient 0.9.0, Git 2.43.0, Emacs 30.1.50, gnu/linux

Please advise. Thanks!

[tarsius]

The internal format used to store suffixes changed in v0.9.0. The old format was supposed to be translated on the fly, but there was a bug, fixed in /338ef1a98b54d5c84e9f7202b1ffb66bb18e9e95. I'll create a release later today (please confirm that this fixes the issue for you).

Additionally, you should not use eval and a wrapper command. Instead use a :setup-children function, something like:

diff --git a/password-menu.el b/password-menu.el
index 7f813a9..1c090c0 100644
--- a/password-menu.el
+++ b/password-menu.el
@@ -177,14 +177,13 @@ (defmacro password-menu--selection-item ()
     `(lambda () (interactive) (password-menu-get-password ,user ,host))))
 
 (defun password-menu-get-prefix-list ()
-  "Get the transient prefix list from the password sources.
-Returns a vector of lists."
-  (let ((picker 0))
-    (apply #'vector
-           (password-menu--get-source-list
-            (append
-             (list (password-menu-picker-string (setq picker (1+ picker))))
-             (password-menu--selection-item))))))
+  "Return list of suffixes corresponding to the password sources."
+  (or password-menu-prefix-list
+      (setq password-menu-prefix-list
+            (let ((picker 0))
+              (password-menu--get-source-list
+               (cons (password-menu-picker-string (cl-incf picker))
+                     (password-menu--selection-item)))))))
 
 (defun password-menu-get-completing-list ()
   "Get the completing list from the password sources."
@@ -198,15 +197,14 @@ (defun password-menu-clear-password-menu ()
   (setq password-menu-prefix-list nil)
   (auth-source-forget-all-cached))
 
-;;;###autoload
-(defun password-menu-transient ()
-  "Show the password transient menu."
-  (interactive)
-  (when (not password-menu-prefix-list)
-    (progn
-      (setq password-menu-prefix-list (vconcat (vector password-menu-prompt) (password-menu-get-prefix-list)))
-      (eval '(transient-define-prefix password-menu-prefix () password-menu-prefix-list))))
-    (password-menu-prefix))
+;;;###autoload (autoload 'password-menu "password-menu" nil t)
+(transient-define-prefix password-menu ()
+  [:class transient-column
+   :description (lambda () password-menu-prompt)
+   :setup-children (lambda (_)
+                     (transient-parse-suffixes
+                      'password-menu
+                      (password-menu-get-prefix-list)))])
 
 ;; Completing-read with a list. Credit:
 ;; https://arialdomartini.github.io/emacs-surround-2

[tarsius]

password-menu-get-prefix-list and its swarm of helpers seem to complicated. How about (on top of the above):

diff --git a/password-menu.el b/password-menu.el
index 1c090c0..656345a 100644
--- a/password-menu.el
+++ b/password-menu.el
@@ -143,47 +143,29 @@ (defun password-menu-picker-string (num)
 
 (defun password-menu--fake-source-data ()
   "Create fake source data."
-  (if password-menu--create-fake-source-data
-      (let ((count 50)
-            (rv ()))
-        (dotimes (n count)
-          (let ((name (concat (char-to-string (+ ?A n)) "-name")))
-            (push (list name "example.com") rv)))
-        (reverse rv))
-    nil))
-
-(defun password-menu-get-sources ()
-    "Get a list of all sources."
-    (append
-     (mapcar (lambda (e) (list
-                          (plist-get e :user)
-                          (plist-get e :host)))
-             (auth-source-search :max password-menu-sources-max))
-     (password-menu--fake-source-data)))
-
-(defmacro password-menu--get-source-list (body)
-  "Get the source list from the password sources with BODY content."
-  `(mapcar
-    (lambda (source)
-      (let ((user (nth 0 source))
-            (host (nth 1 source)))
-        (,@body)))
-      (password-menu-get-sources)))
-
-(defmacro password-menu--selection-item ()
-  "Get the selection USER and HOST item content."
-  `(list
-    (concat user "@" host)
-    `(lambda () (interactive) (password-menu-get-password ,user ,host))))
+  (and password-menu--create-fake-source-data
+       (let ((count 50)
+             (rv ()))
+         (dotimes (n count)
+           (let ((name (concat (char-to-string (+ ?A n)) "-name")))
+             (push (list :user name :host "example.com") rv)))
+         (reverse rv))))
 
 (defun password-menu-get-prefix-list ()
   "Return list of suffixes corresponding to the password sources."
   (or password-menu-prefix-list
       (setq password-menu-prefix-list
             (let ((picker 0))
-              (password-menu--get-source-list
-               (cons (password-menu-picker-string (cl-incf picker))
-                     (password-menu--selection-item)))))))
+              (mapcar (lambda (elt)
+                        (let ((user (plist-get elt :user))
+                              (host (plist-get elt :host)))
+                          (list (password-menu-picker-string (cl-incf picker))
+                                (concat user "@" host)
+                                (lambda ()
+                                  (interactive)
+                                  (password-menu-get-password user host)))))
+                      (nconc (auth-source-search :max password-menu-sources-max)
+                             (password-menu--fake-source-data)))))))
 
 (defun password-menu-get-completing-list ()
   "Get the completing list from the password sources."

Also password-menu--create-fake-source-data doesn't seem like something that should be checked into the main branch. Maybe banish that to a new debug branch, which you occasionally rebase on top of main?

[rnadler]

@tarsius 338ef1a has resolved the issue. Thanks!

Also, thanks for the refactoring suggestions! I will update the package in the near future.