[ios] view controller based status bar

shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.h

@@ -23,6 +23,8 @@ extern const char* const kOrientationUpdateNotificationName;
 extern const char* const kOrientationUpdateNotificationKey;
 extern const char* const kOverlayStyleUpdateNotificationName;
 extern const char* const kOverlayStyleUpdateNotificationKey;
+extern const char* const kStatusBarHiddenUpdateNotificationName;
+extern const char* const kStatusBarHiddenUpdateNotificationKey;
 
 }  // namespace flutter
 

shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.mm

@@ -30,11 +30,21 @@
     "io.flutter.plugin.platform.SystemChromeOverlayNotificationName";
 const char* const kOverlayStyleUpdateNotificationKey =
     "io.flutter.plugin.platform.SystemChromeOverlayNotificationKey";
+const char* const kStatusBarHiddenUpdateNotificationName =
+    "io.flutter.plugin.platform.StatusBarHiddenNotificationName";
+const char* const kStatusBarHiddenUpdateNotificationKey =
+    "io.flutter.plugin.platform.StatusBarHiddenNotificationKey";
 
 }  // namespace flutter
 
 using namespace flutter;
 
+@interface FlutterPlatformPlugin ()
+
+@property(nonatomic, assign) BOOL enableViewControllerBasedStatusBarAppearance;
+
+@end
+
 @implementation FlutterPlatformPlugin {
   fml::WeakPtr<FlutterEngine> _engine;
   // Used to detect whether this device has live text input ability or not.
@@ -47,6 +57,9 @@ - (instancetype)initWithEngine:(fml::WeakPtr<FlutterEngine>)engine {
 
   if (self) {
     _engine = engine;
+    NSNumber* infoValue = [[NSBundle mainBundle]
+        objectForInfoDictionaryKey:@"UIViewControllerBasedStatusBarAppearance"];
+    _enableViewControllerBasedStatusBarAppearance = (infoValue == nil || [infoValue boolValue]);
   }
 
   return self;
@@ -158,14 +171,7 @@ - (void)setSystemChromeApplicationSwitcherDescription:(NSDictionary*)object {
 }
 
 - (void)setSystemChromeEnabledSystemUIOverlays:(NSArray*)overlays {
-  // Checks if the top status bar should be visible. This platform ignores all
-  // other overlays
-
-  // We opt out of view controller based status bar visibility since we want
-  // to be able to modify this on the fly. The key used is
-  // UIViewControllerBasedStatusBarAppearance
-  [UIApplication sharedApplication].statusBarHidden =
-      ![overlays containsObject:@"SystemUiOverlay.top"];
+  BOOL statusBarShouldBeHidden = ![overlays containsObject:@"SystemUiOverlay.top"];
   if ([overlays containsObject:@"SystemUiOverlay.bottom"]) {
     [[NSNotificationCenter defaultCenter]
         postNotificationName:FlutterViewControllerShowHomeIndicator
@@ -175,26 +181,46 @@ - (void)setSystemChromeEnabledSystemUIOverlays:(NSArray*)overlays {
         postNotificationName:FlutterViewControllerHideHomeIndicator
                       object:nil];
   }
+  if (self.enableViewControllerBasedStatusBarAppearance) {
+    // This notification is respected by the iOS embedder
+    [[NSNotificationCenter defaultCenter]
+        postNotificationName:@(kStatusBarHiddenUpdateNotificationName)
+                      object:nil
+                    userInfo:@{
+                      @(kStatusBarHiddenUpdateNotificationKey) : @(statusBarShouldBeHidden)
+                    }];
+  } else {
+    // Checks if the top status bar should be visible. This platform ignores all
+    // other overlays
+
+    // We opt out of view controller based status bar visibility since we want
+    // to be able to modify this on the fly. The key used is
+    // UIViewControllerBasedStatusBarAppearance
+    [UIApplication sharedApplication].statusBarHidden = statusBarShouldBeHidden;
+  }
 }
 
 - (void)setSystemChromeEnabledSystemUIMode:(NSString*)mode {
-  // Checks if the top status bar should be visible, reflected by edge to edge setting. This
-  // platform ignores all other system ui modes.
-
-  // We opt out of view controller based status bar visibility since we want
-  // to be able to modify this on the fly. The key used is
-  // UIViewControllerBasedStatusBarAppearance
-  [UIApplication sharedApplication].statusBarHidden =
-      ![mode isEqualToString:@"SystemUiMode.edgeToEdge"];
-  if ([mode isEqualToString:@"SystemUiMode.edgeToEdge"]) {
+  BOOL edgeToEdge = [mode isEqualToString:@"SystemUiMode.edgeToEdge"];
+  if (self.enableViewControllerBasedStatusBarAppearance) {
+    // This notification is respected by the iOS embedder
     [[NSNotificationCenter defaultCenter]
-        postNotificationName:FlutterViewControllerShowHomeIndicator
-                      object:nil];
+        postNotificationName:@(kStatusBarHiddenUpdateNotificationName)
+                      object:nil
+                    userInfo:@{@(kStatusBarHiddenUpdateNotificationKey) : @(!edgeToEdge)}];
   } else {
-    [[NSNotificationCenter defaultCenter]
-        postNotificationName:FlutterViewControllerHideHomeIndicator
-                      object:nil];
+    // Checks if the top status bar should be visible, reflected by edge to edge setting. This
+    // platform ignores all other system ui modes.
+
+    // We opt out of view controller based status bar visibility since we want
+    // to be able to modify this on the fly. The key used is
+    // UIViewControllerBasedStatusBarAppearance
+    [UIApplication sharedApplication].statusBarHidden = !edgeToEdge;
   }
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:edgeToEdge ? FlutterViewControllerShowHomeIndicator
+                                      : FlutterViewControllerHideHomeIndicator
+                    object:nil];
 }
 
 - (void)restoreSystemChromeSystemUIOverlays {
@@ -220,11 +246,7 @@ - (void)setSystemChromeSystemUIOverlayStyle:(NSDictionary*)message {
     return;
   }
 
-  NSNumber* infoValue = [[NSBundle mainBundle]
-      objectForInfoDictionaryKey:@"UIViewControllerBasedStatusBarAppearance"];
-  Boolean delegateToViewController = (infoValue == nil || [infoValue boolValue]);
-
-  if (delegateToViewController) {
+  if (self.enableViewControllerBasedStatusBarAppearance) {
     // This notification is respected by the iOS embedder
     [[NSNotificationCenter defaultCenter]
         postNotificationName:@(kOverlayStyleUpdateNotificationName)

shell/platform/darwin/ios/framework/Source/FlutterPlatformPluginTest.mm

@@ -8,6 +8,7 @@
 #import "flutter/shell/platform/darwin/common/framework/Headers/FlutterBinaryMessenger.h"
 #import "flutter/shell/platform/darwin/common/framework/Headers/FlutterMacros.h"
 #import "flutter/shell/platform/darwin/ios/framework/Headers/FlutterViewController.h"
+#import "flutter/shell/platform/darwin/ios/framework/Source/FlutterEngine_Internal.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.h"
 #import "flutter/shell/platform/darwin/ios/platform_view_ios.h"
 
@@ -138,4 +139,93 @@ - (void)testWhetherDeviceHasLiveTextInputInvokeCorrectly {
   [self waitForExpectationsWithTimeout:1 handler:nil];
 }
 
+- (void)testViewControllerBasedStatusBarHiddenUpdate {
+  id bundleMock = OCMPartialMock([NSBundle mainBundle]);
+  OCMStub([bundleMock objectForInfoDictionaryKey:@"UIViewControllerBasedStatusBarAppearance"])
+      .andReturn(@YES);
+  {
+    // Enabling system UI overlays to update status bar.
+    FlutterEngine* engine = [[[FlutterEngine alloc] initWithName:@"test" project:nil] autorelease];
+    [engine runWithEntrypoint:nil];
+    FlutterViewController* flutterViewController =
+        [[FlutterViewController alloc] initWithEngine:engine nibName:nil bundle:nil];
+    std::unique_ptr<fml::WeakPtrFactory<FlutterEngine>> _weakFactory =
+        std::make_unique<fml::WeakPtrFactory<FlutterEngine>>(engine);
+    XCTAssertFalse(flutterViewController.prefersStatusBarHidden);
+
+    // Update to hidden.
+    FlutterPlatformPlugin* plugin = [engine platformPlugin];
+
+    XCTestExpectation* enableSystemUIOverlaysCalled =
+        [self expectationWithDescription:@"setEnabledSystemUIOverlays"];
+    FlutterResult resultSet = ^(id result) {
+      [enableSystemUIOverlaysCalled fulfill];
+    };
+    FlutterMethodCall* methodCallSet =
+        [FlutterMethodCall methodCallWithMethodName:@"SystemChrome.setEnabledSystemUIOverlays"
+                                          arguments:@[ @"SystemUiOverlay.bottom" ]];
+    [plugin handleMethodCall:methodCallSet result:resultSet];
+    [self waitForExpectationsWithTimeout:1 handler:nil];
+    XCTAssertTrue(flutterViewController.prefersStatusBarHidden);
+
+    // Update to shown.
+    XCTestExpectation* enableSystemUIOverlaysCalled2 =
+        [self expectationWithDescription:@"setEnabledSystemUIOverlays"];
+    FlutterResult resultSet2 = ^(id result) {
+      [enableSystemUIOverlaysCalled2 fulfill];
+    };
+    FlutterMethodCall* methodCallSet2 =
+        [FlutterMethodCall methodCallWithMethodName:@"SystemChrome.setEnabledSystemUIOverlays"
+                                          arguments:@[ @"SystemUiOverlay.top" ]];
+    [plugin handleMethodCall:methodCallSet2 result:resultSet2];
+    [self waitForExpectationsWithTimeout:1 handler:nil];
+    XCTAssertFalse(flutterViewController.prefersStatusBarHidden);
+
+    [flutterViewController deregisterNotifications];
+    [flutterViewController release];
+  }
+  {
+    // Enable system UI mode to update status bar.
+    FlutterEngine* engine = [[[FlutterEngine alloc] initWithName:@"test" project:nil] autorelease];
+    [engine runWithEntrypoint:nil];
+    FlutterViewController* flutterViewController =
+        [[FlutterViewController alloc] initWithEngine:engine nibName:nil bundle:nil];
+    std::unique_ptr<fml::WeakPtrFactory<FlutterEngine>> _weakFactory =
+        std::make_unique<fml::WeakPtrFactory<FlutterEngine>>(engine);
+    XCTAssertFalse(flutterViewController.prefersStatusBarHidden);
+
+    // Update to hidden.
+    FlutterPlatformPlugin* plugin = [engine platformPlugin];
+
+    XCTestExpectation* enableSystemUIModeCalled =
+        [self expectationWithDescription:@"setEnabledSystemUIMode"];
+    FlutterResult resultSet = ^(id result) {
+      [enableSystemUIModeCalled fulfill];
+    };
+    FlutterMethodCall* methodCallSet =
+        [FlutterMethodCall methodCallWithMethodName:@"SystemChrome.setEnabledSystemUIMode"
+                                          arguments:@"SystemUiMode.immersive"];
+    [plugin handleMethodCall:methodCallSet result:resultSet];
+    [self waitForExpectationsWithTimeout:1 handler:nil];
+    XCTAssertTrue(flutterViewController.prefersStatusBarHidden);
+
+    // Update to shown.
+    XCTestExpectation* enableSystemUIModeCalled2 =
+        [self expectationWithDescription:@"setEnabledSystemUIMode"];
+    FlutterResult resultSet2 = ^(id result) {
+      [enableSystemUIModeCalled2 fulfill];
+    };
+    FlutterMethodCall* methodCallSet2 =
+        [FlutterMethodCall methodCallWithMethodName:@"SystemChrome.setEnabledSystemUIMode"
+                                          arguments:@"SystemUiMode.edgeToEdge"];
+    [plugin handleMethodCall:methodCallSet2 result:resultSet2];
+    [self waitForExpectationsWithTimeout:1 handler:nil];
+    XCTAssertFalse(flutterViewController.prefersStatusBarHidden);
+
+    [flutterViewController deregisterNotifications];
+    [flutterViewController release];
+  }
+  [bundleMock stopMocking];
+}
+
 @end

shell/platform/darwin/ios/framework/Source/FlutterViewController.mm

@@ -103,6 +103,13 @@ @interface FlutterViewController () <FlutterBinaryMessenger, UIScrollViewDelegat
 @property(nonatomic, retain)
     UIRotationGestureRecognizer* rotationGestureRecognizer API_AVAILABLE(ios(13.4));
 
+// Whether the status bar is prefered hidden.
+//
+// The |UIViewController:prefersStatusBarHidden| of this ViewController is overriden and returns
+// `flutterPreferesStatusBarHidden`. Only works when `UIViewControllerBasedStatusBarAppearance` in
+// info.plist of the app project is `true`.
+@property(nonatomic, assign) BOOL flutterPreferesStatusBarHidden;
+
 /**
  * Creates and registers plugins used by this view controller.
  */
@@ -299,6 +306,10 @@ - (void)setupNotificationCenterObservers {
              selector:@selector(onPreferredStatusBarStyleUpdated:)
                  name:@(flutter::kOverlayStyleUpdateNotificationName)
                object:nil];
+  [center addObserver:self
+             selector:@selector(onPreferredStatusBarHiddenUpdated:)
+                 name:@(flutter::kStatusBarHiddenUpdateNotificationName)
+               object:nil];
 
   [center addObserver:self
              selector:@selector(applicationBecameActive:)
@@ -2081,6 +2092,31 @@ - (void)onPreferredStatusBarStyleUpdated:(NSNotification*)notification {
   });
 }
 
+- (void)onPreferredStatusBarHiddenUpdated:(NSNotification*)notification {
+  FML_DCHECK(
+      [notification.name isEqualToString:@(flutter::kStatusBarHiddenUpdateNotificationName)]);
+  // Notifications may not be on the iOS UI thread
+  fml::TaskRunner::RunNowOrPostTask([_engine.get() platformTaskRunner], [&]() {
+    NSDictionary* info = notification.userInfo;
+
+    NSNumber* update = info[@(flutter::kStatusBarHiddenUpdateNotificationKey)];
+
+    if (update == nil) {
+      return;
+    }
+
+    BOOL hidden = [update boolValue];
+    if (hidden != self.flutterPreferesStatusBarHidden) {
+      self.flutterPreferesStatusBarHidden = hidden;
+      [self setNeedsStatusBarAppearanceUpdate];
+    }
+  });
+}
+
+- (BOOL)prefersStatusBarHidden {
+  return self.flutterPreferesStatusBarHidden;
+}
+
 #pragma mark - Platform views
 
 - (std::shared_ptr<flutter::FlutterPlatformViewsController>&)platformViewsController {