iOS keyboard animation synchronization

ci/licenses_golden/licenses_flutter

@@ -4990,6 +4990,8 @@ FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_messa
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.mm
+FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/spring_curve_ios.h
+FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/spring_curve_ios.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/module.modulemap

shell/platform/darwin/ios/BUILD.gn

@@ -129,6 +129,8 @@ source_set("flutter_framework_source") {
     "framework/Source/platform_message_response_darwin.mm",
     "framework/Source/profiler_metrics_ios.h",
     "framework/Source/profiler_metrics_ios.mm",
+    "framework/Source/spring_curve_ios.h",
+    "framework/Source/spring_curve_ios.mm",
     "framework/Source/vsync_waiter_ios.h",
     "framework/Source/vsync_waiter_ios.mm",
     "ios_context.h",

shell/platform/darwin/ios/framework/Source/FlutterViewController.mm

@@ -27,6 +27,7 @@
 #import "flutter/shell/platform/darwin/ios/framework/Source/FlutterTextInputPlugin.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/FlutterView.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.h"
+#import "flutter/shell/platform/darwin/ios/framework/Source/spring_curve_ios.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.h"
 #import "flutter/shell/platform/darwin/ios/platform_view_ios.h"
 #import "flutter/shell/platform/embedder/embedder.h"
@@ -65,6 +66,10 @@ @interface FlutterViewController () <FlutterBinaryMessenger, UIScrollViewDelegat
  */
 @property(nonatomic, assign) double targetViewInsetBottom;
 @property(nonatomic, retain) VSyncClient* keyboardAnimationVSyncClient;
+@property(nonatomic, assign) BOOL keyboardAnimationIsShowing;
+@property(nonatomic, assign) BOOL keyboardAnimationIsCompounding;
+@property(nonatomic, assign) fml::TimePoint keyboardAnimationStartTime;
+@property(nonatomic, assign) CGFloat originalViewInsetBottom;
 @property(nonatomic, assign) BOOL isKeyboardInOrTransitioningFromBackground;
 
 /// VSyncClient for touch events delivery frame rate correction.
@@ -123,6 +128,7 @@ @implementation FlutterViewController {
   // https://github.com/flutter/flutter/issues/35050
   fml::scoped_nsobject<UIScrollView> _scrollView;
   fml::scoped_nsobject<UIView> _keyboardAnimationView;
+  fml::scoped_nsobject<KeyboardSpringCurve> _keyboardSpringCurve;
   MouseState _mouseState;
   // Timestamp after which a scroll inertia cancel event should be inferred.
   NSTimeInterval _scrollInertiaEventStartline;
@@ -594,6 +600,10 @@ - (UIView*)keyboardAnimationView {
   return _keyboardAnimationView.get();
 }
 
+- (KeyboardSpringCurve*)keyboardSpringCurve {
+  return _keyboardSpringCurve.get();
+}
+
 - (UIScreen*)mainScreenIfViewLoaded {
   if (@available(iOS 13.0, *)) {
     if (self.viewIfLoaded == nil) {
@@ -1321,6 +1331,7 @@ - (void)handleKeyboardNotification:(NSNotification*)notification {
   }
 
   NSDictionary* info = notification.userInfo;
+  CGRect beginKeyboardFrame = [[info objectForKey:UIKeyboardFrameBeginUserInfoKey] CGRectValue];
   CGRect keyboardFrame = [info[UIKeyboardFrameEndUserInfoKey] CGRectValue];
   FlutterKeyboardMode keyboardMode = [self calculateKeyboardAttachMode:notification];
   CGFloat calculatedInset = [self calculateKeyboardInset:keyboardFrame keyboardMode:keyboardMode];
@@ -1332,6 +1343,15 @@ - (void)handleKeyboardNotification:(NSNotification*)notification {
 
   self.targetViewInsetBottom = calculatedInset;
   NSTimeInterval duration = [info[UIKeyboardAnimationDurationUserInfoKey] doubleValue];
+
+  BOOL keyboardWillShow = beginKeyboardFrame.origin.y > keyboardFrame.origin.y;
+
+  // Flag for simultaneous compounding animation calls.
+  self.keyboardAnimationIsCompounding = self.keyboardAnimationIsShowing == keyboardWillShow;
+
+  // Mark keyboard as showing or hiding.
+  self.keyboardAnimationIsShowing = keyboardWillShow;
+
   [self startKeyBoardAnimation:duration];
 }
 
@@ -1509,14 +1529,20 @@ - (void)startKeyBoardAnimation:(NSTimeInterval)duration {
 
   if ([self keyboardAnimationView].superview == nil) {
     [self.view addSubview:[self keyboardAnimationView]];
+  } else if (self.keyboardAnimationIsCompounding) {
+    // If keyboardAnimationView has superview, means current animation is running,
+    // and if keyboard animation is in the same direction as current animation, ignore it.
+    return;
   }
 
   // Remove running animation when start another animation.
   [[self keyboardAnimationView].layer removeAllAnimations];
 
-  // Set animation begin value.
+  // Set animation begin value and DisplayLink tracking values.
   [self keyboardAnimationView].frame =
       CGRectMake(0, _viewportMetrics.physical_view_inset_bottom, 0, 0);
+  self.keyboardAnimationStartTime = fml::TimePoint().Now();
+  self.originalViewInsetBottom = _viewportMetrics.physical_view_inset_bottom;
 
   // Invalidate old vsync client if old animation is not completed.
   [self invalidateKeyboardAnimationVSyncClient];
@@ -1527,6 +1553,11 @@ - (void)startKeyBoardAnimation:(NSTimeInterval)duration {
       animations:^{
         // Set end value.
         [self keyboardAnimationView].frame = CGRectMake(0, self.targetViewInsetBottom, 0, 0);
+
+        // Setup keyboard animation interpolation.
+        CAAnimation* keyboardAnimation =
+            [[self keyboardAnimationView].layer animationForKey:@"position"];
+        [self setupKeyboardAnimationCurveIfNeeded:keyboardAnimation];
       }
       completion:^(BOOL finished) {
         if (_keyboardAnimationVSyncClient == currentVsyncClient) {
@@ -1540,6 +1571,21 @@ - (void)startKeyBoardAnimation:(NSTimeInterval)duration {
       }];
 }
 
+- (void)setupKeyboardAnimationCurveIfNeeded:(CAAnimation*)keyboardAnimation {
+  // Set keyboard spring animation details (if animation is CASpringAnimation).
+  if ([keyboardAnimation isKindOfClass:[CASpringAnimation class]]) {
+    CASpringAnimation* keyboardSpringAnimation = (CASpringAnimation*)keyboardAnimation;
+    _keyboardSpringCurve.reset([[KeyboardSpringCurve alloc]
+        initWithStiffness:keyboardSpringAnimation.stiffness
+                  damping:keyboardSpringAnimation.damping
+                     mass:keyboardSpringAnimation.mass
+          initialVelocity:keyboardSpringAnimation.initialVelocity]);
+  } else {
+    // Reset to use fallback keyboard animation tracking.
+    _keyboardSpringCurve.reset();
+  }
+}
+
 - (void)setupKeyboardAnimationVsyncClient {
   auto callback = [weakSelf =
                        [self getWeakPtr]](std::unique_ptr<flutter::FrameTimingsRecorder> recorder) {
@@ -1556,12 +1602,23 @@ - (void)setupKeyboardAnimationVsyncClient {
       // Ensure the keyboardAnimationView is in view hierarchy when animation running.
       [flutterViewController.get().view addSubview:[flutterViewController keyboardAnimationView]];
     }
-    if ([flutterViewController keyboardAnimationView].layer.presentationLayer) {
-      CGFloat value =
-          [flutterViewController keyboardAnimationView].layer.presentationLayer.frame.origin.y;
-      flutterViewController.get()->_viewportMetrics.physical_view_inset_bottom = value;
-      [flutterViewController updateViewportMetrics];
+
+    CGFloat newY;
+    if ([flutterViewController keyboardSpringCurve] == nil) {
+      newY =
+          flutterViewController.get().keyboardAnimationView.layer.presentationLayer.frame.origin.y;
+    } else {
+      double start = flutterViewController.get().originalViewInsetBottom;
+      double end = flutterViewController.get().targetViewInsetBottom;
+      fml::TimeDelta timeElapsed = recorder.get()->GetVsyncTargetTime() -
+                                   flutterViewController.get().keyboardAnimationStartTime;
+      double keyboardAnimationStop =
+          [[flutterViewController keyboardSpringCurve] curveFunc:timeElapsed.ToSecondsF()];
+      newY = start + (end - start) * keyboardAnimationStop;
     }
+
+    flutterViewController.get()->_viewportMetrics.physical_view_inset_bottom = newY;
+    [flutterViewController updateViewportMetrics];
   };
   flutter::Shell& shell = [_engine.get() shell];
   NSAssert(_keyboardAnimationVSyncClient == nil,
@@ -1913,8 +1970,8 @@ - (BOOL)isAlwaysUse24HourFormat {
 }
 
 // The brightness mode of the platform, e.g., light or dark, expressed as a string that
-// is understood by the Flutter framework. See the settings system channel for more
-// information.
+// is understood by the Flutter framework. See the settings
+// system channel for more information.
 - (NSString*)brightnessMode {
   if (@available(iOS 13, *)) {
     UIUserInterfaceStyle style = self.traitCollection.userInterfaceStyle;

shell/platform/darwin/ios/framework/Source/FlutterViewControllerTest.mm

@@ -133,6 +133,8 @@ - (FlutterKeyboardMode)calculateKeyboardAttachMode:(NSNotification*)notification
 - (CGFloat)calculateMultitaskingAdjustment:(CGRect)screenRect keyboardFrame:(CGRect)keyboardFrame;
 - (void)startKeyBoardAnimation:(NSTimeInterval)duration;
 - (void)setupKeyboardAnimationVsyncClient;
+- (UIView*)keyboardAnimationView;
+- (void)setupKeyboardAnimationCurveIfNeeded:(CAAnimation*)keyboardAnimation;
 - (void)ensureViewportMetricsIsCorrect;
 - (void)invalidateKeyboardAnimationVSyncClient;
 - (void)addInternalPlugins;
@@ -190,6 +192,22 @@ - (void)testStartKeyboardAnimationWillInvokeSetupKeyboardAnimationVsyncClient {
   OCMVerify([viewControllerMock setupKeyboardAnimationVsyncClient]);
 }
 
+- (void)testStartKeyboardAnimationWillInvokeSetupKeyboardAnimationCurveIfNeeded {
+  FlutterEngine* engine = [[FlutterEngine alloc] init];
+  [engine runWithEntrypoint:nil];
+  FlutterViewController* viewController = [[FlutterViewController alloc] initWithEngine:engine
+                                                                                nibName:nil
+                                                                                 bundle:nil];
+  FlutterViewController* viewControllerMock = OCMPartialMock(viewController);
+  viewControllerMock.targetViewInsetBottom = 100;
+  [viewControllerMock startKeyBoardAnimation:0.25];
+
+  CAAnimation* keyboardAnimation =
+      [[viewControllerMock keyboardAnimationView].layer animationForKey:@"position"];
+
+  OCMVerify([viewControllerMock setupKeyboardAnimationCurveIfNeeded:keyboardAnimation]);
+}
+
 - (void)testShouldIgnoreKeyboardNotification {
   FlutterEngine* mockEngine = OCMPartialMock([[FlutterEngine alloc] init]);
   [mockEngine createShell:@"" libraryURI:@"" initialRoute:nil];

shell/platform/darwin/ios/framework/Source/spring_curve_ios.h

@@ -0,0 +1,24 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_SPRING_CURVE_IOS_H_
+#define FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_SPRING_CURVE_IOS_H_
+
+#include <Foundation/NSObject.h>
+
+@interface KeyboardSpringCurve : NSObject
+
+- (instancetype)initWithStiffness:(double)stiffness
+                          damping:(double)damping
+                             mass:(double)mass
+                  initialVelocity:(double)initialVelocity;
+
+- (double)curveFunc:(double)t;
+
+@property(nonatomic, assign) double initialVelocity;
+@property(nonatomic, assign) double dampingRatio;
+@property(nonatomic, assign) double omega;
+@end
+
+#endif  // FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_SPRING_CURVE_IOS_H_

shell/platform/darwin/ios/framework/Source/spring_curve_ios.mm

@@ -0,0 +1,53 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "flutter/shell/platform/darwin/ios/framework/Source/spring_curve_ios.h"
+
+#include <Foundation/Foundation.h>
+
+// Spring calculation adapted from Pan Yusheng's research project.
+// See: https://github.com/CosynPa/RevealSpringAnimation.
+@implementation KeyboardSpringCurve
+- (instancetype)initWithStiffness:(double)stiffness
+                          damping:(double)damping
+                             mass:(double)mass
+                  initialVelocity:(double)initialVelocity {
+  self = [super init];
+  if (self) {
+    _dampingRatio = MIN(1.0, damping / 2 / sqrt(stiffness * mass));
+    _initialVelocity = initialVelocity;
+
+    double response = MAX(1e-5, 2 * M_PI / sqrt(stiffness / mass));
+    _omega = 2 * M_PI / response;
+  }
+  return self;
+}
+
+- (double)curveFunc:(double)t {
+  double v0 = self.initialVelocity;
+  double zeta = self.dampingRatio;
+
+  double y;
+  if (abs(zeta - 1.0) < 1e-8) {
+    double c1 = -1.0;
+    double c2 = v0 - self.omega;
+    y = (c1 + c2 * t) * exp(-self.omega * t);
+  } else if (zeta > 1) {
+    double s1 = self.omega * (-zeta + sqrt(zeta * zeta - 1));
+    double s2 = self.omega * (-zeta - sqrt(zeta * zeta - 1));
+    double c1 = (-s2 - v0) / (s2 - s1);
+    double c2 = (s1 + v0) / (s2 - s1);
+    y = c1 * exp(s1 * t) + c2 * exp(s2 * t);
+  } else {
+    double a = -self.omega * zeta;
+    double b = self.omega * sqrt(1 - zeta * zeta);
+    double c2 = (v0 + a) / b;
+    double theta = atan(c2);
+    // Alternatively y = (-cos(b * t) + c2 * sin(b * t)) * exp(a * t)
+    y = sqrt(1 + c2 * c2) * exp(a * t) * cos(b * t + theta + M_PI);
+  }
+
+  return y + 1;
+}
+@end