Add an Info.plist flag to enable MacOS platform views preview support

ci/licenses_golden/licenses_flutter

@@ -1056,6 +1056,7 @@ FILE: ../../../flutter/shell/platform/darwin/macos/framework/Info.plist
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterAppDelegate.mm
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterBackingStoreData.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterBackingStoreData.mm
+FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterConstants.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterDartProject.mm
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterDartProject_Internal.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterEngine.mm

shell/platform/darwin/macos/framework/Source/FlutterConstants.h

@@ -0,0 +1,6 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+// The name of the Info.plist flag to enable the embedded MacOS views preview.
+const char* const kEmbeddedViewsPreview = "io.flutter_embedded_views_preview";

shell/platform/darwin/macos/framework/Source/FlutterEngine.mm

@@ -310,10 +310,17 @@ - (BOOL)runWithEntrypoint:(NSString*)entrypoint {
       },
       .identifier = ++sTaskRunnerIdentifiers,
   };
+
+  bool embedded_views_preview_enabled = [FlutterPlatformViewController embeddedViewsEnabled];
+
   const FlutterCustomTaskRunners custom_task_runners = {
       .struct_size = sizeof(FlutterCustomTaskRunners),
       .platform_task_runner = &cocoa_task_runner_description,
-  };
+      // If platform views are enabled, set the render thread to the platform thread.
+      // Otherwise the render thread is created separately in embedder_thread_host.cc.
+      .render_task_runner =
+          embedded_views_preview_enabled ? &cocoa_task_runner_description : nullptr};
+
   flutterArguments.custom_task_runners = &custom_task_runners;
 
   [self loadAOTData:_project.assetsPath];

shell/platform/darwin/macos/framework/Source/FlutterPlatformViewController.mm

@@ -4,20 +4,29 @@
 
 #include "flutter/fml/logging.h"
 
+#import "flutter/shell/platform/darwin/macos/framework/Source/FlutterConstants.h"
 #import "flutter/shell/platform/darwin/macos/framework/Source/FlutterPlatformViewController_Internal.h"
 
-@implementation FlutterPlatformViewController
+@implementation FlutterPlatformViewController {
+  bool _embeddedViewsEnabled;
+}
 
 - (instancetype)init {
   self = [super init];
 
-  self->_platformViewFactories = [[NSMutableDictionary alloc] init];
+  _platformViewFactories = [[NSMutableDictionary alloc] init];
+  [self setEmbeddedViewsEnabled:[FlutterPlatformViewController embeddedViewsEnabled]];
   return self;
 }
 
 - (void)onCreateWithViewId:(int64_t)viewId
                   viewType:(nonnull NSString*)viewType
                     result:(nonnull FlutterResult)result {
+  if (!_embeddedViewsEnabled) {
+    NSLog(@"Must set `io.flutter_embedded_views_preview` to true in Info.plist to enable platform "
+          @"views");
+    return;
+  }
   if (_platformViews.count(viewId) != 0) {
     result([FlutterError errorWithCode:@"recreating_view"
                                message:@"trying to create an already created view"
@@ -42,6 +51,12 @@ - (void)onCreateWithViewId:(int64_t)viewId
 }
 
 - (void)onDisposeWithViewId:(int64_t)viewId result:(nonnull FlutterResult)result {
+  if (!_embeddedViewsEnabled) {
+    NSLog(@"Must set `io.flutter_embedded_views_preview` to true in Info.plist to enable platform "
+          @"views");
+    return;
+  }
+
   if (_platformViews.count(viewId) == 0) {
     result([FlutterError errorWithCode:@"unknown_view"
                                message:@"trying to dispose an unknown"
@@ -56,6 +71,11 @@ - (void)onDisposeWithViewId:(int64_t)viewId result:(nonnull FlutterResult)result
 
 - (void)registerViewFactory:(nonnull NSObject<FlutterPlatformViewFactory>*)factory
                      withId:(nonnull NSString*)factoryId {
+  if (!_embeddedViewsEnabled) {
+    NSLog(@"Must set `io.flutter_embedded_views_preview` to true in Info.plist to enable platform "
+          @"views");
+    return;
+  }
   _platformViewFactories[factoryId] = factory;
 }
 
@@ -89,4 +109,12 @@ - (void)disposePlatformViews {
   _platformViewsToDispose.clear();
 }
 
+- (void)setEmbeddedViewsEnabled:(bool)embeddedViewsEnabled {
+  _embeddedViewsEnabled = embeddedViewsEnabled;
+}
+
++ (bool)embeddedViewsEnabled {
+  return [[[NSBundle mainBundle] objectForInfoDictionaryKey:@(kEmbeddedViewsPreview)] boolValue];
+}
+
 @end

shell/platform/darwin/macos/framework/Source/FlutterPlatformViewControllerTest.mm

@@ -11,9 +11,33 @@
 
 namespace flutter::testing {
 
+TEST(FlutterPlatformViewController, EmbeddedViewsDisabled) {
+  // Use id so we can access handleMethodCall method.
+  id platformViewController = [[FlutterPlatformViewController alloc] init];
+  [platformViewController setEmbeddedViewsEnabled:false];
+
+  FlutterMethodCall* methodCall =
+      [FlutterMethodCall methodCallWithMethodName:@"create"
+                                        arguments:@{
+                                          @"id" : @2,
+                                          @"viewType" : @"FlutterPlatformViewMock"
+                                        }];
+
+  __block bool called = false;
+  FlutterResult result = ^(id result) {
+    called = true;
+  };
+
+  [platformViewController handleMethodCall:methodCall result:result];
+
+  // The call should not have happened if embeddedViewsEnabled is false.
+  EXPECT_FALSE(called);
+}
+
 TEST(FlutterPlatformViewController, TestCreatePlatformViewNoMatchingViewType) {
   // Use id so we can access handleMethodCall method.
   id platformViewController = [[FlutterPlatformViewController alloc] init];
+  [platformViewController setEmbeddedViewsEnabled:true];
 
   FlutterMethodCall* methodCall =
       [FlutterMethodCall methodCallWithMethodName:@"create"
@@ -38,6 +62,7 @@
 TEST(FlutterPlatformViewController, TestRegisterPlatformViewFactoryAndCreate) {
   // Use id so we can access handleMethodCall method.
   id platformViewController = [[FlutterPlatformViewController alloc] init];
+  [platformViewController setEmbeddedViewsEnabled:true];
 
   FlutterPlatformViewMockFactory* factory = [FlutterPlatformViewMockFactory alloc];
 
@@ -65,6 +90,7 @@
 TEST(FlutterPlatformViewController, TestCreateAndDispose) {
   // Use id so we can access handleMethodCall method.
   id platformViewController = [[FlutterPlatformViewController alloc] init];
+  [platformViewController setEmbeddedViewsEnabled:true];
 
   FlutterPlatformViewMockFactory* factory = [FlutterPlatformViewMockFactory alloc];
 
@@ -108,6 +134,7 @@
 TEST(FlutterPlatformViewController, TestDisposeOnMissingViewId) {
   // Use id so we can access handleMethodCall method.
   id platformViewController = [[FlutterPlatformViewController alloc] init];
+  [platformViewController setEmbeddedViewsEnabled:true];
 
   FlutterMethodCall* methodCall =
       [FlutterMethodCall methodCallWithMethodName:@"dispose"

shell/platform/darwin/macos/framework/Source/FlutterPlatformViewController_Internal.h

@@ -55,4 +55,15 @@
  */
 - (void)disposePlatformViews;
 
+/**
+ * Set _embedded_views_preview_enabled value.
+ */
+- (void)setEmbeddedViewsEnabled:(bool)embeddedViewsEnabled;
+
+/**
+ * Return whether or not platform views are enabled by looking for the
+ * io.flutter_embedded_views_preview flag in Info.plist.
+ */
++ (bool)embeddedViewsEnabled;
+
 @end

shell/platform/darwin/macos/framework/Source/FlutterView.mm

@@ -4,6 +4,7 @@
 
 #import "flutter/shell/platform/darwin/macos/framework/Source/FlutterView.h"
 
+#import "flutter/shell/platform/darwin/macos/framework/Source/FlutterPlatformViewController_Internal.h"
 #import "flutter/shell/platform/darwin/macos/framework/Source/FlutterResizeSynchronizer.h"
 #import "flutter/shell/platform/darwin/macos/framework/Source/FlutterSurfaceManager.h"
 #import "flutter/shell/platform/darwin/macos/framework/Source/MacOSGLContextSwitch.h"
@@ -15,6 +16,7 @@ @interface FlutterView () <FlutterResizeSynchronizerDelegate> {
   __weak id<FlutterViewReshapeListener> _reshapeListener;
   FlutterResizeSynchronizer* _resizeSynchronizer;
   FlutterSurfaceManager* _surfaceManager;
+  bool _embedded_views_preview_enabled;
 }
 
 @end
@@ -42,6 +44,9 @@ - (instancetype)initWithFrame:(NSRect)frame
 
     _reshapeListener = reshapeListener;
   }
+
+  _embedded_views_preview_enabled = [FlutterPlatformViewController embeddedViewsEnabled];
+
   return self;
 }
 
@@ -67,15 +72,30 @@ - (int)frameBufferIDForSize:(CGSize)size {
 }
 
 - (void)present {
-  [_resizeSynchronizer requestCommit];
+  // If _embedded_views_preview_enabled is true, the main and raster
+  // threads are merged. Thus we cannot call resizeSynchronizer::requestCommit
+  // as it blocks on the raster thread.
+  if (_embedded_views_preview_enabled) {
+    [self resizeSynchronizerFlush:_resizeSynchronizer];
+    [self resizeSynchronizerCommit:_resizeSynchronizer];
+  } else {
+    [_resizeSynchronizer requestCommit];
+  }
 }
 
 - (void)reshaped {
   CGSize scaledSize = [self convertSizeToBacking:self.bounds.size];
-  [_resizeSynchronizer beginResize:scaledSize
-                            notify:^{
-                              [_reshapeListener viewDidReshape:self];
-                            }];
+  // If _embedded_views_preview_enabled is true, the main and raster
+  // threads are merged. Thus we cannot call resizeSynchronizer::beginResize
+  // as it blocks on the main thread.
+  if (_embedded_views_preview_enabled) {
+    [_reshapeListener viewDidReshape:self];
+  } else {
+    [_resizeSynchronizer beginResize:scaledSize
+                              notify:^{
+                                [_reshapeListener viewDidReshape:self];
+                              }];
+  }
 }
 
 #pragma mark - NSView overrides