Add range(start => stop, length)

base/range.jl

@@ -94,6 +94,42 @@ range(start; length::Union{Integer,Nothing}=nothing, stop=nothing, step=nothing)
 range(start, stop; length::Union{Integer,Nothing}=nothing, step=nothing) =
     _range2(start, step, stop, length)
 
+"""
+    range(start => stop, length)
+
+Given a `start` to `stop` [`Pair`](@ref) and an integer `length`,
+construct a range iterator of `length` elements whose first element is `start`
+and last element is `stop`.
+
+In contrast to the [`:`](@ref) range syntaxes `start:stop` and `start:step:stop`,
+this method ensures the endpoints are hit exactly and a `length` must be provided.
+The `step` is always computed based upon the provided endpoints and length.
+In contrast to the other `range` methods, no keyword arguments are accepted.
+
+Special care is taken to ensure intermediate values are computed rationally.
+To avoid this induced overhead, see the [`LinRange`](@ref) constructor.
+
+!!! compat "Julia 1.7"
+    Providing `start => stop` as a `Pair` requires at least Julia 1.7.
+
+# Examples
+```jldoctest
+julia> range(1 => 5, 3)
+1.0:2.0:5.0
+
+julia> range(0 => 100, 101)
+0.0:1.0:100.0
+
+julia> range(5 => 3, 3)
+5.0:-1.0:3.0
+```
+"""
+range(start_stop::Pair, length::Integer) =
+    _range(start_stop.first, nothing, start_stop.second, length)
+
+range(start_stop::Pair, length::Nothing = nothing) =
+    throw(ArgumentError("`length` must be specified after $start_stop"))
+
 _range2(start, ::Nothing, stop, ::Nothing) =
     throw(ArgumentError("At least one of `length` or `step` must be specified"))
 

test/ranges.jl

@@ -1610,6 +1610,18 @@ end
     @test_throws ArgumentError range(1, 100)
 end
 
+@testset "range with start => stop Pair argument" begin
+    for starts in [-1, 0, 1, 10]
+        for stops in [-2, 0, 2, 100]
+            for lengths in [2, 10, 100]
+                @test range( starts => stops, lengths) === range(starts, stops; length = lengths)
+            end
+        end
+    end
+    @test_throws ArgumentError range( 1 => 5 )
+    @test_throws ArgumentError range( -1 => -5 , nothing )
+end
+
 @testset "Reverse empty ranges" begin
     @test reverse(1:0) === 0:-1:1
     @test reverse(Base.OneTo(0)) === 0:-1:1