Refactor Lib_file_deps handling

* Move setting up glob aliases to Lib_file_deps
* Allow only fixed number of extensions as we only setup a few of them
* Do not setup extraneous dependencies for cmo's

Signed-off-by: Rudi Grinberg <[email protected]>

Author: rgrinberg

src/compilation_context.ml

@@ -16,7 +16,7 @@ module Includes = struct
       let cmi_includes =
         Arg_spec.S [ iflags
                    ; Hidden_deps
-                       (Lib_file_deps.L.file_deps sctx libs ~exts:[".cmi"])
+                       (Lib_file_deps.file_deps sctx libs ~groups:[Cmi])
                    ]
       in
       let cmx_includes =
@@ -26,12 +26,13 @@ module Includes = struct
               ( if opaque then
                   List.map libs ~f:(fun lib ->
                     (lib, if Lib.is_local lib then
-                       [".cmi"]
+                       [Lib_file_deps.Group.Cmi]
                      else
-                       [".cmi"; ".cmx"]))
-                  |> Lib_file_deps.L.file_deps_with_exts sctx
+                       [Cmi; Cmx]))
+                  |> Lib_file_deps.file_deps_with_exts sctx
                 else
-                  Lib_file_deps.L.file_deps sctx libs ~exts:[".cmi"; ".cmx"]
+                  Lib_file_deps.file_deps sctx libs
+                    ~groups:[Lib_file_deps.Group.Cmi; Cmx]
               )
           ]
       in

src/lib_file_deps.ml

@@ -2,53 +2,80 @@ open Stdune
 open Dune_file
 open Build_system
 
-let string_of_exts = String.concat ~sep:"-and-"
-
-let lib_files_alias ~dir ~name ~exts =
-  Alias.make (sprintf "lib-%s%s-all"
-                (Lib_name.to_string name) (string_of_exts exts)) ~dir
-
-let setup_file_deps_alias t ~dir ~exts lib files =
-  Super_context.add_alias_deps t
-    (lib_files_alias ~dir ~name:(Library.best_name lib) ~exts) files
-
-let setup_file_deps_group_alias t ~dir ~exts lib =
-  setup_file_deps_alias t lib ~dir ~exts
-    (List.map exts ~f:(fun ext ->
-       Alias.stamp_file
-         (lib_files_alias ~dir ~name:(Library.best_name lib) ~exts:[ext]))
-     |> Path.Set.of_list)
-
-let setup_file_deps sctx ~dir ~lib ~modules =
-  let add_cms ~cm_kind ~init = List.fold_left ~init ~f:(fun acc m ->
-    match Module.cm_public_file m cm_kind with
-    | None -> acc
-    | Some fn -> Path.Set.add acc fn)
-  in
-  List.iter Cm_kind.all ~f:(fun cm_kind ->
-    let files = add_cms ~cm_kind ~init:Path.Set.empty modules in
-    setup_file_deps_alias sctx ~dir lib ~exts:[Cm_kind.ext cm_kind]
-      files);
-
-  setup_file_deps_group_alias sctx ~dir lib ~exts:[".cmi"; ".cmx"];
-  setup_file_deps_alias sctx ~dir lib ~exts:[".h"]
-    (List.map lib.install_c_headers ~f:(fun header ->
-       Path.relative dir (header ^ ".h"))
-     |> Path.Set.of_list)
-
-module L = struct
-  let file_deps_of_lib t (lib : Lib.t) ~exts =
-    if Lib.is_local lib then
-      Alias.stamp_file
-        (lib_files_alias ~dir:(Lib.src_dir lib) ~name:(Lib.name lib) ~exts)
-    else
-      (* suppose that all the files of an external lib are at the same place *)
-      Build_system.stamp_file_for_files_of (Super_context.build_system t)
-        ~dir:(Obj_dir.public_cmi_dir (Lib.obj_dir lib)) ~ext:(string_of_exts exts)
-
-  let file_deps_with_exts t lib_exts =
-    List.rev_map lib_exts ~f:(fun (lib, exts) -> file_deps_of_lib t lib ~exts)
-
-  let file_deps t libs ~exts =
-    List.rev_map libs ~f:(file_deps_of_lib t ~exts)
+module Group = struct
+  type t =
+    | Cmi
+    | Cmx
+    | Header
+
+  let to_string = function
+    | Cmi -> ".cmi"
+    | Cmx -> ".cmx"
+    | Header -> ".h"
+
+  let of_cm_kind = function
+    | Cm_kind.Cmx -> Cmx
+    | Cmi -> Cmi
+    | Cmo -> Exn.code_error "Lib_file_deps.Group.of_cm_kind: Cmo" []
+
+  module L = struct
+    let to_string l =
+      List.map l ~f:to_string
+      |> List.sort ~compare:String.compare
+      |> String.concat  ~sep:"-and-"
+
+    let alias t ~dir ~name =
+      sprintf "lib-%s%s-all" (Lib_name.to_string name) (to_string t)
+      |> Alias.make ~dir
+
+    let setup_alias t ~sctx ~dir ~lib ~files =
+      Super_context.add_alias_deps
+        sctx
+        (alias t ~dir ~name:(Library.best_name lib))
+        files
+
+    let setup_file_deps_group_alias t ~sctx ~dir ~lib =
+      setup_alias t ~sctx ~dir ~lib ~files:(
+        List.map t ~f:(fun t ->
+          Alias.stamp_file (alias [t] ~dir ~name:(Library.best_name lib)))
+        |> Path.Set.of_list
+      )
+  end
 end
+
+let setup_file_deps =
+  let cm_kinds = [Cm_kind.Cmx; Cmi] in
+  let groups = List.map ~f:Group.of_cm_kind cm_kinds in
+  fun sctx ~dir ~lib ~modules ->
+    let add_cms ~cm_kind =
+      List.fold_left ~f:(fun acc m ->
+        match Module.cm_public_file m cm_kind with
+        | None -> acc
+        | Some fn -> Path.Set.add acc fn)
+    in
+    List.iter cm_kinds ~f:(fun cm_kind ->
+      let files = add_cms ~cm_kind ~init:Path.Set.empty modules in
+      let groups = [Group.of_cm_kind cm_kind] in
+      Group.L.setup_alias groups ~sctx ~dir ~lib ~files);
+    Group.L.setup_file_deps_group_alias groups ~sctx ~dir ~lib;
+    Group.L.setup_alias [Header] ~sctx ~dir ~lib ~files:(
+      List.map lib.install_c_headers ~f:(fun header ->
+        Path.relative dir (header ^ ".h"))
+      |> Path.Set.of_list)
+
+let file_deps_of_lib t (lib : Lib.t) ~groups =
+  if Lib.is_local lib then
+    Alias.stamp_file
+      (Group.L.alias groups ~dir:(Lib.src_dir lib) ~name:(Lib.name lib))
+  else
+    (* suppose that all the files of an external lib are at the same place *)
+    Build_system.stamp_file_for_files_of
+      (Super_context.build_system t)
+      ~dir:(Obj_dir.public_cmi_dir (Lib.obj_dir lib))
+      ~ext:(Group.L.to_string groups)
+
+let file_deps_with_exts t =
+  List.rev_map ~f:(fun (lib, groups) -> file_deps_of_lib t lib ~groups)
+
+let file_deps t libs ~groups =
+  List.rev_map libs ~f:(file_deps_of_lib t ~groups)

src/lib_file_deps.mli

@@ -1,16 +1,24 @@
 open Stdune
 
-module L : sig
+module Group : sig
+  type t =
+    | Cmi
+    | Cmx
+    | Header
+end
 
-  (** [file_deps t libs ~ext] returns a list of path dependencies for all the
-      files with extension [ext] of libraries [libs]. *)
-  val file_deps : Super_context.t -> Lib.L.t -> exts:string list -> Path.t list
+(** [file_deps t libs ~files] returns a list of path dependencies for all the
+    files with extension [files] of libraries [libs]. *)
+val file_deps
+  :  Super_context.t
+  -> Lib.L.t
+  -> groups:Group.t list
+  -> Path.t list
 
-  val file_deps_with_exts
-    :  Super_context.t
-    -> (Lib.t * string list) list
-    -> Path.t list
-end
+val file_deps_with_exts
+  :  Super_context.t
+  -> (Lib.t * Group.t list) list
+  -> Path.t list
 
 (** Setup alias dependencies for library artifacts grouped by extensions *)
 val setup_file_deps

src/lib_rules.ml

@@ -282,7 +282,8 @@ module Gen (P : Install_rules.Params) = struct
         [ Hidden_deps h_files
         ; Arg_spec.of_result_map requires ~f:(fun libs ->
             S [ Lib.L.c_include_flags libs ~stdlib_dir:ctx.stdlib_dir
-              ; Hidden_deps (Lib_file_deps.L.file_deps sctx libs ~exts:[".h"])
+              ; Hidden_deps (Lib_file_deps.file_deps sctx libs
+                               ~groups:[Lib_file_deps.Group.Header])
               ])
         ]
     in