treefmt-nix/programs/golines.nix at main · numtide/treefmt-nix · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
{
  lib,
  config,
  mkFormatterModule,
  ...
}:
let
  cfg = config.programs.golines;
in
{
  meta.maintainers = [ "gabyx" ];

  imports = [
    (mkFormatterModule {
      name = "golines";
      package = "golines";
      args = [
        "-w"
        # Do not reformat tags due to destructive operations:
        # See https://github.com/segmentio/golines/issues/161
        "--no-reformat-tags"
      ];
      includes = [ "*.go" ];
      excludes = [ "vendor/*" ];
    })
  ];

  options.programs.golines = {
    maxLength = lib.mkOption {
      type = with lib.types; nullOr int;
      default = null;
      example = 100;
      description = ''
        Target maximum line length (default: 100)
      '';
    };

    tabLength = lib.mkOption {
      type = with lib.types; nullOr int;
      default = null;
      example = 4;
      description = ''
        Length of a tab (default: 4)
      '';
    };
  };

  config = lib.mkIf cfg.enable {
    settings.formatter.golines = {
      command = "${cfg.package}/bin/golines";
      options =
        (lib.optionals (cfg.maxLength != null) [
          "--max-len"
          (toString cfg.maxLength)
        ])
        ++ (lib.optionals (cfg.tabLength != null) [
          "--tab-len"
          (toString cfg.tabLength)
        ]);
    };
  };
}