Merge pull request #141 from lambdalisue/new-rename

Support complex renaming via 'rename' action of 'file' or 'dict' scheme

Author: lambdalisue

autoload/fern/internal/rename_solver.vim

@@ -0,0 +1,107 @@
+let s:ESCAPE_PATTERN = '^$~.*[]\'
+
+function! fern#internal#rename_solver#solve(pairs, ...) abort
+  let options = extend({
+        \ 'exist': { p -> getftype(p) !=# '' },
+        \ 'tempname': { _ -> tempname() },
+        \ 'isdirectory': { p -> isdirectory(p) },
+        \}, a:0 ? a:1 : {},
+        \)
+  let Exist = options.exist
+  let Tempname = options.tempname
+  let IsDirectory = options.isdirectory
+  " Sort by 'dst' depth
+  let pairs = sort(copy(a:pairs), funcref('s:compare'))
+  " Build steps from given pairs
+  let steps = []
+  let tears = []
+  let src_map = s:dict(map(
+        \ copy(a:pairs),
+        \ { -> [v:val[0], 1] },
+        \))
+  for [src, dst] in pairs
+    let rsrc_map = s:dict(map(
+          \ copy(a:pairs),
+          \ { -> [s:replace(v:val[0], steps), 1] },
+          \))
+    let rsrc = s:replace(src, steps)
+    if rsrc ==# dst
+      continue
+    endif
+    let rdst = s:replace_backword(dst, steps)
+    if get(rsrc_map, dst)
+      let tmp = Tempname(dst)
+      call add(steps, [rsrc, tmp, '', ''])
+      call add(tears, [tmp, dst, src, rdst])
+    elseif !get(src_map, rdst) && Exist(rdst)
+      throw printf('Destination "%s" already exist as "%s"', dst, rdst)
+    else
+      call add(steps, [rsrc, dst, src, rdst])
+    endif
+  endfor
+  let steps += tears
+  " Check 'dst' uniqueness
+  let dup = s:find_duplication(map(copy(steps), { -> v:val[1] }))
+  if !empty(dup)
+    throw printf('Destination "%s" appears more than once', dup)
+  endif
+  " Check parent directories of 'dst'
+  for [rsrc, dst, src, rdst] in steps
+    let prv = rdst
+    let cur = fern#internal#path#dirname(prv)
+    while cur !=# '' && cur !=# prv
+      if !Exist(cur)
+        break
+      elseif !IsDirectory(cur)
+        throw printf(
+              \ 'Destination "%s" in "%s" is not directory',
+              \ s:replace(cur, steps),
+              \ dst,
+              \)
+      endif
+      let prv = cur
+      let cur = fern#internal#path#dirname(cur)
+    endwhile
+  endfor
+  return map(steps, { -> v:val[0:1] })
+endfunction
+
+function! s:dict(entries) abort
+  let m = {}
+  call map(copy(a:entries), { _, v -> extend(m, { v[0]: v[1] }) })
+  return m
+endfunction
+
+function! s:compare(a, b) abort
+  let a = len(split(a:a[1], '[/\\]'))
+  let b = len(split(a:b[1], '[/\\]'))
+  return a is# b ? 0 : a > b ? 1 : -1
+endfunction
+
+function! s:find_duplication(list) abort
+  let seen = {}
+  for item in a:list
+    if has_key(seen, item)
+      return item
+    endif
+    let seen[item] = 1
+  endfor
+endfunction
+
+function! s:replace(text, applied) abort
+  let text = a:text
+  for item in a:applied
+    let [src, dst] = item[0:1]
+    let text = substitute(text, escape(src, s:ESCAPE_PATTERN), dst, '')
+  endfor
+  return text
+endfunction
+
+function! s:replace_backword(text, applied) abort
+  let text = a:text
+  for item in reverse(copy(a:applied))
+    let [src, dst] = item[0:1]
+    let text = substitute(text, escape(dst, s:ESCAPE_PATTERN), src, '')
+  endfor
+  return text
+endfunction

autoload/fern/internal/renamer.vim

@@ -0,0 +1,130 @@
+let s:Promise = vital#fern#import('Async.Promise')
+let s:ESCAPE_PATTERN = '^$~.*[]\'
+
+function! fern#internal#replacer#start(factory, ...) abort
+  let options = extend({
+        \ 'bufname': printf('fern-replacer:%s', sha256(localtime()))[:7],
+        \ 'opener': 'vsplit',
+        \ 'cursor': [1, 1],
+        \ 'is_drawer': v:false,
+        \ 'modifiers': [],
+        \}, a:0 ? a:1 : {},
+        \)
+  return s:Promise.new(funcref('s:executor', [a:factory, options]))
+endfunction
+
+function! s:executor(factory, options, resolve, reject) abort
+  call fern#internal#buffer#open(a:options.bufname, {
+        \ 'opener': a:options.opener,
+        \ 'locator': a:options.is_drawer,
+        \ 'keepalt': !a:options.is_drawer && g:fern#keepalt_on_edit,
+        \ 'keepjumps': !a:options.is_drawer && g:fern#keepjumps_on_edit,
+        \ 'mods': 'noautocmd',
+        \})
+
+  setlocal buftype=acwrite bufhidden=wipe
+  setlocal noswapfile nobuflisted
+  setlocal nowrap
+  setlocal filetype=fern-replacer
+
+  let b:fern_replacer_resolve = a:resolve
+  let b:fern_replacer_factory = a:factory
+  let b:fern_replacer_candidates = a:factory()
+  let b:fern_replacer_modifiers = a:options.modifiers
+
+  augroup fern_replacer_internal
+    autocmd! * <buffer>
+    autocmd BufReadCmd  <buffer> call s:BufReadCmd()
+    autocmd BufWriteCmd <buffer> call s:BufWriteCmd()
+    autocmd ColorScheme <buffer> call s:highlight()
+  augroup END
+
+  call s:highlight()
+  call s:syntax()
+
+  " Do NOT allow to add/remove lines
+  nnoremap <buffer><silent> <Plug>(fern-replacer-p) :<C-u>call <SID>map_paste(0)<CR>
+  nnoremap <buffer><silent> <Plug>(fern-replacer-P) :<C-u>call <SID>map_paste(-1)<CR>
+  nnoremap <buffer><silent> <Plug>(fern-replacer-warn) :<C-u>call <SID>map_warn()<CR>
+  inoremap <buffer><silent><expr> <Plug>(fern-replacer-warn) <SID>map_warn()
+  nnoremap <buffer><silent> dd 0D
+  nmap <buffer> p <Plug>(fern-replacer-p)
+  nmap <buffer> P <Plug>(fern-replacer-P)
+  nmap <buffer> o <Plug>(fern-replacer-warn)
+  nmap <buffer> O <Plug>(fern-replacer-warn)
+  imap <buffer> <C-m> <Plug>(fern-replacer-warn)
+  imap <buffer> <Return> <Plug>(fern-replacer-warn)
+  edit
+  call cursor(a:options.cursor)
+endfunction
+
+function! s:map_warn() abort
+  echohl WarningMsg
+  echo 'Newline is prohibited in the replacer buffer'
+  echohl None
+  return ''
+endfunction
+
+function! s:map_paste(offset) abort
+  let line = getline('.')
+  let v = substitute(getreg(), '\r\?\n', '', 'g')
+  let c = col('.') + a:offset - 1
+  let l = line[:c]
+  let r = line[c + 1:]
+  call setline(line('.'), l . v . r)
+endfunction
+
+function! s:BufReadCmd() abort
+  let b:fern_replacer_candidates = b:fern_replacer_factory()
+  call s:syntax()
+  call setline(1, b:fern_replacer_candidates)
+endfunction
+
+function! s:BufWriteCmd() abort
+  if !&modifiable
+    return
+  endif
+  let candidates = b:fern_replacer_candidates
+  let result = []
+  for index in range(len(candidates))
+    let src = candidates[index]
+    let dst = getline(index + 1)
+    if empty(dst) || dst ==# src
+      continue
+    endif
+    call add(result, [src, dst])
+  endfor
+  try
+    for Modifier in b:fern_replacer_modifiers
+      let result = Modifier(result)
+    endfor
+    let Resolve = b:fern_replacer_resolve
+    set nomodified
+    close
+    call Resolve(result)
+  catch
+    echohl ErrorMsg
+    echo '[fern] Please fix the following error first to continue or cancel with ":q!"'
+    echo printf('[fern] %s', substitute(v:exception, '^Vim(.*):', '', ''))
+    echohl None
+  endtry
+endfunction
+
+function! s:syntax() abort
+  syntax clear
+  syntax match FernReplacerModified '^.\+$'
+
+  for index in range(len(b:fern_replacer_candidates))
+    let candidate = b:fern_replacer_candidates[index]
+    execute printf(
+          \ 'syntax match FernReplacerOriginal ''^\%%%dl%s$''',
+          \ index + 1,
+          \ escape(candidate, s:ESCAPE_PATTERN),
+          \)
+  endfor
+endfunction
+
+function! s:highlight() abort
+  highlight default link FernReplacerOriginal Normal
+  highlight default link FernReplacerModified Special
+endfunction