Merge pull request #135 from lambdalisue/rename-buffer

Apply buffer modification after move/rename/trash/remove action

Author: lambdalisue

autoload/fern/scheme/file/bufutil.vim

@@ -0,0 +1,28 @@
+function! fern#scheme#file#bufutil#removes(paths) abort
+  for path in a:paths
+    let bufnr = bufnr(path)
+    if bufnr is# -1 || getbufvar(bufnr, '&modified')
+      continue
+    endif
+    execute printf('silent! noautocmd %dbwipeout', bufnr)
+  endfor
+endfunction
+
+function! fern#scheme#file#bufutil#moves(pairs) abort
+  let bufnr_saved = bufnr('%')
+  let hidden_saved = &hidden
+  set hidden
+  try
+    for [src, dst] in a:pairs
+      let bufnr = bufnr(src)
+      if bufnr is# -1
+        return
+      endif
+      execute printf('silent! noautocmd keepjumps keepalt %dbuffer', bufnr)
+      execute printf('silent! noautocmd keepalt file %s', fnameescape(dst))
+    endfor
+  finally
+    execute printf('keepjumps keepalt %dbuffer', bufnr_saved)
+    let &hidden = hidden_saved
+  endtry
+endfunction

autoload/fern/scheme/file/mapping.vim

@@ -107,6 +107,7 @@ function! s:map_move(helper) abort
   let nodes = a:helper.sync.get_selected_nodes()
   let token = a:helper.fern.source.token
   let ps = []
+  let bufutil_pairs = []
   for node in nodes
     let src = node._path
     let dst = input(
@@ -118,9 +119,11 @@ function! s:map_move(helper) abort
       continue
     endif
     call add(ps, fern#scheme#file#shutil#move(src, dst, token))
+    call add(bufutil_pairs, [src, dst])
   endfor
   let root = a:helper.sync.get_root_node()
   return s:Promise.all(ps)
+        \.then({ -> fern#scheme#file#bufutil#moves(bufutil_pairs) })
         \.then({ -> a:helper.async.collapse_modified_nodes(nodes) })
         \.then({ -> a:helper.async.reload_node(root.__key) })
         \.then({ -> a:helper.async.redraw() })
@@ -143,12 +146,16 @@ function! s:map_trash(helper) abort
   endif
   let token = a:helper.fern.source.token
   let ps = []
+  let bufutil_paths = []
   for node in nodes
-    echo printf('Trash %s', node._path)
-    call add(ps, fern#scheme#file#shutil#trash(node._path, token))
+    let path = node._path
+    echo printf('Trash %s', path)
+    call add(ps, fern#scheme#file#shutil#trash(path, token))
+    call add(bufutil_paths, path)
   endfor
   let root = a:helper.sync.get_root_node()
   return s:Promise.all(ps)
+        \.then({ -> fern#scheme#file#bufutil#removes(bufutil_paths) })
         \.then({ -> a:helper.async.collapse_modified_nodes(nodes) })
         \.then({ -> a:helper.async.reload_node(root.__key) })
         \.then({ -> a:helper.async.redraw() })
@@ -171,12 +178,16 @@ function! s:map_remove(helper) abort
   endif
   let token = a:helper.fern.source.token
   let ps = []
+  let bufutil_paths = []
   for node in nodes
-    echo printf('Remove %s', node._path)
-    call add(ps, fern#scheme#file#shutil#remove(node._path, token))
+    let path = node._path
+    echo printf('Remove %s', path)
+    call add(ps, fern#scheme#file#shutil#remove(path, token))
+    call add(bufutil_paths, path)
   endfor
   let root = a:helper.sync.get_root_node()
   return s:Promise.all(ps)
+        \.then({ -> fern#scheme#file#bufutil#removes(bufutil_paths) })
         \.then({ -> a:helper.async.collapse_modified_nodes(nodes) })
         \.then({ -> a:helper.async.reload_node(root.__key) })
         \.then({ -> a:helper.async.redraw() })

autoload/fern/scheme/file/mapping/rename.vim

@@ -57,8 +57,7 @@ endfunction
 function! s:_map_rename(helper, result) abort
   let token = a:helper.fern.source.token
   let ps = []
-  for pair in a:result
-    let [src, dst] = pair
+  for [src, dst] in a:result
     if !filereadable(src) && !isdirectory(src)
       echohl WarningMsg
       echo printf('%s does not exist', src)
@@ -68,5 +67,6 @@ function! s:_map_rename(helper, result) abort
     call add(ps, fern#scheme#file#shutil#move(src, dst, token))
   endfor
   return s:Promise.all(ps)
+        \.then({ -> fern#scheme#file#bufutil#moves(a:result) })
         \.then({ -> len(ps) })
 endfunction

test/behavior/buffer-rename.vimspec

@@ -0,0 +1,63 @@
+Describe buffer-rename
+  Before
+    let workdir = tempname()
+    lockvar workdir
+    call mkdir(workdir, 'p')
+    call writefile([], fern#internal#filepath#join([workdir, 'alpha']))
+    call writefile([], fern#internal#filepath#join([workdir, 'beta']))
+    call writefile([], fern#internal#filepath#join([workdir, 'gamma']))
+    %bwipeout!
+  End
+
+  After
+    %bwipeout!
+    call delete(workdir, 'rf')
+    set hidden&
+  End
+
+  It "move" action will update bufname of a corresponding opened buffer
+    execute printf('edit %s', fnameescape(fern#internal#filepath#join([workdir, 'alpha'])))
+    execute printf('Fern %s -wait', fnameescape(workdir))
+    Assert Match(execute('ls'), '\<alpha\>')
+    call timer_start(0, { -> feedkeys("\<C-w>OMEGA\<CR>") })
+    execute "normal ggj\<Plug>(fern-action-move)\<Plug>(fern-wait)"
+    Assert Equals(getline(1, '$'), [
+          \ printf('%s ', fnamemodify(workdir, ':t')),
+          \ '|  OMEGA ',
+          \ '|  beta ',
+          \ '|  gamma ',
+          \])
+    Assert NotMatch(execute('ls'), '\<alpha\>')
+    Assert Match(execute('ls'), '\<OMEGA\>')
+  End
+
+  It "remove" action will remove a corresponding opened buffer
+    execute printf('edit %s', fnameescape(fern#internal#filepath#join([workdir, 'alpha'])))
+    execute printf('Fern %s -wait', fnameescape(workdir))
+    Assert Match(execute('ls'), '\<alpha\>')
+    call timer_start(0, { -> feedkeys("y\<CR>") })
+    execute "normal ggj\<Plug>(fern-action-remove)\<Plug>(fern-wait)"
+    Assert Equals(getline(1, '$'), [
+          \ printf('%s ', fnamemodify(workdir, ':t')),
+          \ '|  beta ',
+          \ '|  gamma ',
+          \])
+    Assert NotMatch(execute('ls'), '\<alpha\>')
+  End
+
+  It "remove" action does NOT remove a corresponding opened buffer if modified
+    set hidden
+    execute printf('edit %s', fnameescape(fern#internal#filepath#join([workdir, 'alpha'])))
+    call append(0, ["Hello World"])
+    execute printf('Fern %s -wait', fnameescape(workdir))
+    Assert Match(execute('ls'), '\<alpha\>')
+    call timer_start(0, { -> feedkeys("y\<CR>") })
+    execute "normal ggj\<Plug>(fern-action-remove)\<Plug>(fern-wait)"
+    Assert Equals(getline(1, '$'), [
+          \ printf('%s ', fnamemodify(workdir, ':t')),
+          \ '|  beta ',
+          \ '|  gamma ',
+          \])
+    Assert Match(execute('ls'), '\<alpha\>')
+  End
+End