stripe-react-native/ios/NewArch/CardFieldComponentView.mm at bd7205536128272f7d255d1d6f0c3ff7f4e52120 · janicduplessis/stripe-react-native · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
#import "CardFieldComponentView.h"

#import <react/renderer/components/rnstripe/ComponentDescriptors.h>
#import <react/renderer/components/rnstripe/EventEmitters.h>
#import <react/renderer/components/rnstripe/Props.h>
#import <react/renderer/components/rnstripe/RCTComponentViewHelpers.h>

#import <React/RCTConversions.h>
#import <React/RCTFabricComponentsPlugins.h>
#import "StripeNewArchConversions.h"
#import "StripeSwiftInterop.h"

using namespace facebook::react;
using namespace stripe::react;

@interface CardFieldComponentView () <RCTCardFieldViewProtocol>
@end

@implementation CardFieldComponentView {
  CardFieldView *_view;
}

// Needed because of this: https://github.com/facebook/react-native/pull/37274
+ (void)load
{
  [super load];
}

- (instancetype)initWithFrame:(CGRect)frame
{
  if (self = [super initWithFrame:frame]) {
    static const auto defaultProps = std::make_shared<const CardFieldProps>();
    _props = defaultProps;
    [self prepareView];
  }

  return self;
}

- (void)prepareView
{
  _view = [[CardFieldView alloc] initWithFrame:self.frame];
  self.contentView = _view;

  __weak __typeof(self) weakSelf = self;

  _view.onCardChange = ^(NSDictionary *event) {
    __typeof(self) strongSelf = weakSelf;
    if (!strongSelf || !strongSelf->_eventEmitter) {
      return;
    }
    CardFieldEventEmitter::OnCardChange emitterEvent = {.card = convertIdToFollyDynamic(event[@"card"])};
    std::static_pointer_cast<const CardFieldEventEmitter>(strongSelf->_eventEmitter)
        ->onCardChange(std::move(emitterEvent));
  };

  _view.onFocusChange = ^(NSDictionary *event) {
    __typeof(self) strongSelf = weakSelf;
    if (!strongSelf || !strongSelf->_eventEmitter) {
      return;
    }
    CardFieldEventEmitter::OnFocusChange emitterEvent = {.focusedField = RCTStringFromNSString(event[@"focusedField"])};
    std::static_pointer_cast<const CardFieldEventEmitter>(strongSelf->_eventEmitter)
        ->onFocusChange(std::move(emitterEvent));
  };
}

- (void)updateProps:(const facebook::react::Props::Shared &)props
           oldProps:(const facebook::react::Props::Shared &)oldProps
{
  const auto &newViewProps = *std::static_pointer_cast<const CardFieldProps>(props);

  _view.autofocus = newViewProps.autofocus;
  _view.cardStyle = convertFollyDynamicToNSDictionary(newViewProps.cardStyle);
  _view.countryCode = RCTNSStringFromStringNilIfEmpty(newViewProps.countryCode);
  _view.dangerouslyGetFullCardDetails = newViewProps.dangerouslyGetFullCardDetails;
  _view.disabled = newViewProps.disabled;
  _view.onBehalfOf = RCTNSStringFromStringNilIfEmpty(newViewProps.onBehalfOf);
  _view.placeholders = convertFollyDynamicToNSDictionary(newViewProps.placeholders);
  _view.postalCodeEnabled = newViewProps.postalCodeEnabled;
  _view.preferredNetworks = convertIntVectorToNSArray(newViewProps.preferredNetworks);

  [super updateProps:props oldProps:oldProps];
}

#pragma mark - RCTComponentViewProtocol

+ (ComponentDescriptorProvider)componentDescriptorProvider
{
  return concreteComponentDescriptorProvider<CardFieldComponentDescriptor>();
}

- (void)prepareForRecycle
{
  [super prepareForRecycle];
  [self prepareView];
}

- (void)handleCommand:(const NSString *)commandName args:(const NSArray *)args
{
  RCTCardFieldHandleCommand(self, commandName, args);
}

- (void)blur
{
  [_view blur];
}

- (void)focus
{
  [_view focus];
}

- (void)clear
{
  [_view clear];
}

@end

Class<RCTComponentViewProtocol> CardFieldCls(void)
{
  return CardFieldComponentView.class;
}