module-interfaces/interface.nix at caeb171fde3a6ce2dc61f4e59834df9e7bf584a0 · fricklerhandwerk/module-interfaces · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
# SPDX-License-Identifier: EUPL-1.2
/**
  Collection of interfaces
*/
{ lib, config, ... }:
let
  inherit (lib) mkOption types;
in
{
  options.interfaces = mkOption {
    type =
      with types;
      attrsOf (
        submodule (interface: {
          options = {
            description = mkOption {
              type = str;
            };
            input = mkOption {
              type = deferredModule;
            };
            output = mkOption {
              type = deferredModule;
            };
            consumer = mkOption {
              type = optionType;
              readOnly = true;
              default = submodule (consumer: {
                options = {
                  provider = mkOption {
                    type = interface.config.provider;
                  };
                  input = mkOption {
                    type = submodule interface.config.input;
                  };
                  output = mkOption {
                    type = submodule interface.config.output;
                    readOnly = true;
                    default = (consumer.config.provider consumer.config.input).output;
                  };
                };
              });
            };
            provider = mkOption {
              type = optionType;
              readOnly = true;
              default = functionTo (
                submodule (provider: {
                  options = {
                    input = mkOption {
                      type = submodule interface.config.input;
                    };
                    output = mkOption {
                      type = submodule interface.config.output;
                    };
                  };
                })
              );
            };
          };
        })
      );
  };
}