Add an iOS PlatformViewsController for creating/disposing UIViews.

* Adds a FlutterPlatformViewFactory protocol - a simple factory protocol to be implemented by plugins
  that exposes a UIView for embeeding in Flutter apps.
* Adds a FlutterPlatformView protocol, which is used to associate a
  dispose callback with a `UIView` created by a FlutterPlatformViewFactory.
* Exposes a registerViewFactory method in FlutterPluginRegistrar.
* Implements the `flutter/platform_views` system channel on iOS, allowing
  Dart code to ask for creation/destruction of UIViews.

Author: amirh

shell/platform/darwin/ios/BUILD.gn

@@ -29,6 +29,7 @@ _flutter_framework_headers = [
   "framework/Headers/FlutterHeadlessDartRunner.h",
   "framework/Headers/FlutterMacros.h",
   "framework/Headers/FlutterNavigationController.h",
+  "framework/Headers/FlutterPlatformViews.h",
   "framework/Headers/FlutterPlugin.h",
   "framework/Headers/FlutterPluginAppLifeCycleDelegate.h",
   "framework/Headers/FlutterTexture.h",
@@ -55,6 +56,8 @@ shared_library("create_flutter_framework_dylib") {
     "framework/Source/FlutterNavigationController.mm",
     "framework/Source/FlutterPlatformPlugin.h",
     "framework/Source/FlutterPlatformPlugin.mm",
+    "framework/Source/FlutterPlatformViews_Internal.h",
+    "framework/Source/FlutterPlatformViews.mm",
     "framework/Source/FlutterPluginAppLifeCycleDelegate.mm",
     "framework/Source/FlutterStandardCodec.mm",
     "framework/Source/FlutterStandardCodec_Internal.h",

shell/platform/darwin/ios/framework/Headers/Flutter.h

@@ -50,6 +50,7 @@
 #include "FlutterHeadlessDartRunner.h"
 #include "FlutterMacros.h"
 #include "FlutterNavigationController.h"
+#include "FlutterPlatformViews.h"
 #include "FlutterPlugin.h"
 #include "FlutterPluginAppLifeCycleDelegate.h"
 #include "FlutterTexture.h"

shell/platform/darwin/ios/framework/Headers/FlutterPlatformViews.h

@@ -0,0 +1,63 @@
+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_FLUTTERPLATFORMVIEWS_H_
+#define FLUTTER_FLUTTERPLATFORMVIEWS_H_
+
+#import <CoreMedia/CoreMedia.h>
+#import <Foundation/Foundation.h>
+#import <UIKit/UIKit.h>
+
+#include "FlutterCodecs.h"
+#include "FlutterMacros.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ An instance of a `UIView` created by a `FlutterPlatformViewFactory`.
+
+ This protocol is used to associate a view with a dispose callback.
+ */
+FLUTTER_EXPORT
+@protocol FlutterPlatformView <NSObject>
+- (UIView*)view;
+/**
+ Called when the Flutter engine no longer needs this `view`.
+
+ The implementation of this method should release any kept for this view.
+ */
+- (void)dispose;
+@end
+
+FLUTTER_EXPORT
+@protocol FlutterPlatformViewFactory <NSObject>
+/**
+ Create a `FlutterPlatformView`.
+
+ Implemented by iOS code that expose a `UIView` for embedding in a Flutter app.
+
+ The implementation of this method should create a new `UIView` and return a `FlutterPlatformView`
+ that wraps it.
+
+ - Parameters:
+   - frame: The rectangle for the newly created `UIView` measued in points.
+   - args: Parameters for creating the `UIView` sent from the Dart side of the Flutter app.
+     If `createArgsCodec` is not implemented, or if no creation arguments were sent from the Dart
+     code, this will be null. Otherwise this will be the value sent from the Dart code as decoded by
+     `createArgsCodec`.
+ */
+- (NSObject<FlutterPlatformView>*)createWithFrame:(CGRect)frame andArgs:(id _Nullable)args;
+
+/**
+ Returns the `FlutterMessageCodec` for decoding the args parameter of `createWithFrame`.
+
+ Only needs to be implemented if `createWithFrame` needs an arguments parameter.
+ */
+@optional
+- (NSObject<FlutterMessageCodec>*)createArgsCodec;
+@end
+
+NS_ASSUME_NONNULL_END
+
+#endif  // FLUTTER_FLUTTERPLATFORMVIEWS_H_

shell/platform/darwin/ios/framework/Headers/FlutterPlugin.h

@@ -10,6 +10,7 @@
 #include "FlutterBinaryMessenger.h"
 #include "FlutterChannels.h"
 #include "FlutterCodecs.h"
+#include "FlutterPlatformViews.h"
 #include "FlutterTexture.h"
 
 NS_ASSUME_NONNULL_BEGIN
@@ -203,6 +204,19 @@ NS_ASSUME_NONNULL_BEGIN
  */
 - (NSObject<FlutterTextureRegistry>*)textures;
 
+/**
+ Registers a `FlutterPlatformViewFactory` for creation of platfrom views.
+
+ Plugins expose `UIView` for embedding in Flutter apps by registering a view factory.
+
+ - Parameters:
+   - factory: The view factory that will be registered.
+   - factoryId:: A unique identifier for the factory, the Dart code of the Flutter app can use
+     this identifier to request creation of a `UIView` by the registered factory.
+ */
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(NSString*)factoryId;
+
 /**
  Publishes a value for external use of the plugin.
 

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews.mm

@@ -0,0 +1,92 @@
+#include <map>
+#include <memory>
+#include <string>
+
+#include "FlutterPlatformViews_Internal.h"
+#include "flutter/fml/platform/darwin/scoped_nsobject.h"
+#include "flutter/shell/platform/darwin/ios/framework/Headers/FlutterChannels.h"
+
+@implementation FlutterPlatformViewsController {
+  fml::scoped_nsobject<FlutterMethodChannel> _channel;
+  std::map<std::string, fml::scoped_nsobject<NSObject<FlutterPlatformViewFactory>>> _factories;
+  std::map<long, fml::scoped_nsobject<NSObject<FlutterPlatformView>>> _views;
+}
+
+- (instancetype)init:(NSObject<FlutterBinaryMessenger>*)withMessenger {
+  if (self = [super init]) {
+    _channel.reset([[FlutterMethodChannel alloc]
+           initWithName:@"flutter/platform_views"
+        binaryMessenger:withMessenger
+                  codec:[FlutterStandardMethodCodec sharedInstance]]);
+    [_channel.get() setMethodCallHandler:^(FlutterMethodCall* call, FlutterResult result) {
+      [self methodCallHandler:call withResult:result];
+    }];
+  }
+  return self;
+}
+
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(NSString*)factoryId {
+  std::string idString([factoryId UTF8String]);
+  NSAssert(_factories.count(idString) == 0,
+           ([NSString stringWithFormat:@"Can't register an already registered view factory: %@",
+                                       factoryId]));
+  _factories[idString] =
+      fml::scoped_nsobject<NSObject<FlutterPlatformViewFactory>>([factory retain]);
+}
+
+- (void)methodCallHandler:(FlutterMethodCall*)call withResult:(FlutterResult)result {
+  if ([[call method] isEqualToString:@"create"]) {
+    [self handleCreate:call withResult:result];
+  } else if ([[call method] isEqualToString:@"dispose"]) {
+    [self handleDispose:call withResult:result];
+  } else {
+    result(FlutterMethodNotImplemented);
+  }
+}
+
+- (void)handleCreate:(FlutterMethodCall*)call withResult:(FlutterResult)result {
+  NSDictionary<NSString*, id>* args = [call arguments];
+
+  long viewId = [args[@"id"] longValue];
+  std::string viewType([args[@"viewType"] UTF8String]);
+
+  if (_views[viewId] != nil) {
+    result([FlutterError errorWithCode:@"recreating_view"
+                               message:@"trying to create an already created view"
+                               details:[NSString stringWithFormat:@"view id: '%ld'", viewId]]);
+  }
+
+  NSObject<FlutterPlatformViewFactory>* factory = _factories[viewType].get();
+  if (factory == nil) {
+    result([FlutterError errorWithCode:@"unregistered_view_type"
+                               message:@"trying to create a view with an unregistered type"
+                               details:[NSString stringWithFormat:@"unregistered view type: '%@'",
+                                                                  args[@"viewType"]]]);
+    return;
+  }
+
+  // TODO(amirh): decode and pass the creation args.
+  _views[viewId] =
+      fml::scoped_nsobject<NSObject<FlutterPlatformView>>([[factory createWithFrame:CGRectZero
+                                                                            andArgs:nil] retain]);
+  result(nil);
+}
+
+- (void)handleDispose:(FlutterMethodCall*)call withResult:(FlutterResult)result {
+  NSDictionary<NSString*, id>* args = [call arguments];
+  long viewId = [args[@"id"] longValue];
+
+  if (_views[viewId] == nil) {
+    result([FlutterError errorWithCode:@"unknown_view"
+                               message:@"trying to dispose an unknown"
+                               details:[NSString stringWithFormat:@"view id: '%ld'", viewId]]);
+    return;
+  }
+
+  [_views[viewId] dispose];
+  _views.erase(viewId);
+  result(nil);
+}
+
+@end

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h

@@ -0,0 +1,21 @@
+// Copyright 2018 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWS_INTERNAL_H_
+#define FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWS_INTERNAL_H_
+
+#include "flutter/shell/common/shell.h"
+#include "flutter/shell/platform/darwin/ios/framework/Headers/FlutterBinaryMessenger.h"
+#include "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlatformViews.h"
+
+@interface FlutterPlatformViewsController : NSObject
+
+- (instancetype)init:(NSObject<FlutterBinaryMessenger>*)withMessenger;
+
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(NSString*)factoryId;
+
+@end
+
+#endif  // FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWS_INTERNAL_H_

shell/platform/darwin/ios/framework/Source/FlutterViewController.mm

@@ -4,6 +4,7 @@
 
 #define FML_USED_ON_EMBEDDER
 
+#import "flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h"
 #import "flutter/shell/platform/darwin/ios/framework/Source/FlutterViewController_Internal.h"
 
 #include <memory>
@@ -52,6 +53,7 @@ @implementation FlutterViewController {
   fml::scoped_nsobject<FlutterView> _flutterView;
   fml::scoped_nsobject<UIView> _splashScreenView;
   fml::ScopedBlock<void (^)(void)> _flutterViewRenderedCallback;
+  fml::scoped_nsobject<FlutterPlatformViewsController> _platformViewsController;
   UIInterfaceOrientationMask _orientationPreferences;
   UIStatusBarStyle _statusBarStyle;
   blink::ViewportMetrics _viewportMetrics;
@@ -105,6 +107,7 @@ - (void)performCommonViewControllerInitialization {
     [self setupChannels];
     [self setupNotificationCenterObservers];
 
+    _platformViewsController.reset([[FlutterPlatformViewsController alloc] init:self]);
     _pluginPublications = [NSMutableDictionary new];
   }
 }
@@ -1056,6 +1059,12 @@ - (void)onPreferredStatusBarStyleUpdated:(NSNotification*)notification {
   });
 }
 
+#pragma mark - Platform views
+
+- (FlutterPlatformViewsController*)platformViewsController {
+  return _platformViewsController.get();
+}
+
 #pragma mark - FlutterBinaryMessenger
 
 - (void)sendOnChannel:(NSString*)channel message:(NSData*)message {
@@ -1162,6 +1171,11 @@ - (void)dealloc {
   return _flutterViewController;
 }
 
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(NSString*)factoryId {
+  [[_flutterViewController platformViewsController] registerViewFactory:factory withId:factoryId];
+}
+
 - (void)publish:(NSObject*)value {
   _flutterViewController.pluginPublications[_pluginKey] = value;
 }