gradle-rocker-plugin/build.gradle at main · etiennestuder/gradle-rocker-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
import org.gradle.util.GradleVersion

import static java.lang.Integer.parseInt

plugins {
    id 'java-gradle-plugin'
    alias(libs.plugins.publish)
    alias(libs.plugins.github.actions)
    id 'groovy'
}

group = 'nu.studer'
version = '3.3.2-DEV'

repositories {
    mavenCentral()
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
        vendor = JvmVendorSpec.BELLSOFT
    }
}

def dvBuildScan = develocity.buildScan
testing {
    suites {
        test {
            dependencies {
                implementation libs.spock
                runtimeOnly libs.junit5.launcher
            }
            targets {
                //noinspection ConfigurationAvoidance
                all {
                    testTask.configure { Test t ->
                        t.maxParallelForks = 1 // there is currently only a single test class
                        t.useJUnitPlatform()

                        String testJavaRuntimeVersion = findProperty('testJavaRuntimeVersion') ?: '25'
                        t.javaLauncher.set(javaToolchains.launcherFor { spec ->
                            spec.languageVersion.set(JavaLanguageVersion.of(testJavaRuntimeVersion))
                            dvBuildScan.value(t.identityPath.asString() + "#jvmVersion", testJavaRuntimeVersion)
                        } as Provider<? extends JavaLauncher>)

                        String testGradleVersion = findProperty('testGradleVersion') ?: GradleVersion.current().version
                        t.systemProperty 'testContext.gradleVersion', testGradleVersion
                        dvBuildScan.value(t.identityPath.asString() + "#gradleVersion", testGradleVersion)

                        def incompatibleJavaVsGradleVersions =
                                parseInt(testJavaRuntimeVersion) < 17 && GradleVersion.version(testGradleVersion) >= GradleVersion.version('9.0') ||
                                parseInt(testJavaRuntimeVersion) > 20 && GradleVersion.version(testGradleVersion) < GradleVersion.version('8.6') ||
                                parseInt(testJavaRuntimeVersion) > 16 && GradleVersion.version(testGradleVersion) < GradleVersion.version('7.3') ||
                                parseInt(testJavaRuntimeVersion) > 15 && GradleVersion.version(testGradleVersion) < GradleVersion.version('7.0')
                        if (incompatibleJavaVsGradleVersions) {
                            t.enabled = false
                        }
                    }
                }
            }
        }
    }
}

tasks.withType(AbstractCompile).configureEach {
    options.compilerArgs <<
            "-Werror" <<
            "-Xlint:all"
}

tasks.withType(Javadoc).configureEach {
    options.addStringOption('Xdoclint:none', '-quiet')
}

tasks.withType(ValidatePlugins.class).configureEach {
    failOnWarning = true
    enableStricterValidation = true
}

gradlePlugin {
    website = 'https://github.com/etiennestuder/gradle-rocker-plugin'
    vcsUrl = 'https://github.com/etiennestuder/gradle-rocker-plugin'
    plugins {
        pluginDevPlugin {
            id = 'nu.studer.rocker'
            displayName = 'gradle-rocker-plugin'
            description = 'Gradle plugin that integrates the Rocker template engine.'
            tags.set(['rocker'])
            implementationClass = 'nu.studer.gradle.rocker.RockerPlugin'
            compatibility {
                features {
                    configurationCache = true
                }
            }
        }
    }
}