NeTEx: Extracteur de Network (#5341)

Author: ptitfred

apps/transport/lib/netex/calendars_streaming_parser.ex

@@ -5,16 +5,13 @@ defmodule Transport.NeTEx.CalendarsStreamingParser do
 
   @behaviour Saxy.Handler
 
-  import Transport.NeTEx.NeTExHelpers
   import Transport.NeTEx.SaxyHelpers
 
   def initial_state do
-    %{
-      capture: false,
-      current_tree: [],
+    capturing_initial_state(%{
       calendars: [],
       operating_periods: []
-    }
+    })
   end
 
   def unwrap_result(final_state), do: final_state.calendars ++ final_state.operating_periods
@@ -83,16 +80,6 @@ defmodule Transport.NeTEx.CalendarsStreamingParser do
     update_in(state, [:current_operating_period], &(&1 |> Map.put(field, value)))
   end
 
-  defp push(state, element), do: state |> update_in([:current_tree], &(&1 ++ [element]))
-
-  defp pop(state), do: update_in(state, [:current_tree], &(&1 |> List.delete_at(-1)))
-
-  defp reset_tree(state), do: %{state | current_tree: []}
-
-  defp start_capture(state), do: %{state | capture: true}
-
-  defp stop_capture(state), do: %{state | capture: false}
-
   defp register_calendar(state) do
     current = state.current_calendar
 

apps/transport/lib/netex/netex_archive_parser.ex

@@ -116,6 +116,31 @@ defmodule Transport.NeTEx.ArchiveParser do
     read_all(zip_file_name, &read_types_of_frames!/2)
   end
 
+  @doc """
+  Inside a zip archive opened with `Unzip`, parse a given file (pointed by
+  `file_name`) and extract the networks. The file is read in streaming
+  fashion to save memory, but the stop places are stacked in a list (all in
+  memory at once).
+  """
+  def read_networks(%Unzip{} = unzip, file_name) do
+    parse_stream(unzip, file_name, Transport.NeTEx.NetworkParser)
+  end
+
+  @doc """
+  Like read_networks/2 but raises on errors.
+  """
+  def read_networks!(%Unzip{} = unzip, file_name) do
+    parse_stream!(unzip, file_name, Transport.NeTEx.NetworkParser)
+  end
+
+  def read_all_networks(zip_file_name) do
+    read_all(zip_file_name, &read_networks/2)
+  end
+
+  def read_all_networks!(zip_file_name) do
+    read_all(zip_file_name, &read_networks!/2)
+  end
+
   defp parse_stream(unzip, file_name, parser) do
     extension = Path.extname(file_name)
 

apps/transport/lib/netex/network_parser.ex

@@ -0,0 +1,50 @@
+defmodule Transport.NeTEx.NetworkParser do
+  @moduledoc """
+  Extract network informations.
+  """
+
+  @behaviour Saxy.Handler
+
+  import Transport.NeTEx.SaxyHelpers
+
+  def initial_state do
+    capturing_initial_state(%{
+      networks: []
+    })
+  end
+
+  def unwrap_result(final_state), do: final_state.networks
+
+  def handle_event(:start_element, {element, _attributes}, state) do
+    state =
+      case {element, state[:capture]} do
+        {"Network", _} ->
+          state |> push(element) |> start_capture()
+
+        {_, true} ->
+          state |> push(element)
+
+        _ ->
+          state
+      end
+
+    {:ok, state}
+  end
+
+  def handle_event(:end_element, "Network", state) do
+    {:ok, state |> stop_capture() |> pop()}
+  end
+
+  def handle_event(:end_element, _, state) do
+    {:ok, state |> pop()}
+  end
+
+  def handle_event(:characters, chars, state)
+      when state.capture and state.current_tree == ["Network", "Name"] do
+    {:ok, state |> register_network(chars)}
+  end
+
+  def handle_event(_, _, state), do: {:ok, state}
+
+  defp register_network(state, network), do: update_in(state, [:networks], &(&1 ++ [network]))
+end

apps/transport/lib/netex/saxy_helpers.ex

@@ -37,4 +37,21 @@ defmodule Transport.NeTEx.SaxyHelpers do
         end
     end
   end
+
+  def capturing_initial_state(initial_state) do
+    Map.merge(initial_state, %{
+      capture: false,
+      current_tree: []
+    })
+  end
+
+  def push(state, element), do: state |> update_in([:current_tree], &(&1 ++ [element]))
+
+  def pop(state), do: update_in(state, [:current_tree], &(&1 |> List.delete_at(-1)))
+
+  def reset_tree(state), do: %{state | current_tree: []}
+
+  def start_capture(state), do: %{state | capture: true}
+
+  def stop_capture(state), do: %{state | capture: false}
 end

apps/transport/lib/netex/service_calendars_streaming_parser.ex

@@ -91,16 +91,6 @@ defmodule Transport.NeTEx.ServiceCalendarsStreamingParser do
     update_in(state, [:current_service_calendar], &(&1 |> Map.put(field, value)))
   end
 
-  defp push(state, element), do: state |> update_in([:current_tree], &(&1 ++ [element]))
-
-  defp pop(state), do: update_in(state, [:current_tree], &(&1 |> List.delete_at(-1)))
-
-  defp reset_tree(state), do: %{state | current_tree: []}
-
-  defp start_capture(state), do: %{state | capture: true}
-
-  defp stop_capture(state), do: %{state | capture: false}
-
   defp register_service_calendar(state) do
     current = state.current_service_calendar
 

apps/transport/lib/validators/netex/metadata_extractor.ex

@@ -4,7 +4,13 @@ defmodule Transport.Validators.NeTEx.MetadataExtractor do
   - start_date and end_date (from calendar and service calendars)
   """
 
+  alias Transport.NeTEx.ArchiveParser
+
   def extract(filepath) do
+    Map.merge(extract_validity_dates(filepath), extract_networks(filepath))
+  end
+
+  def extract_validity_dates(filepath) do
     case validity_dates(filepath) do
       {start_date, end_date} ->
         %{
@@ -19,6 +25,12 @@ defmodule Transport.Validators.NeTEx.MetadataExtractor do
     _ -> no_validity_dates()
   end
 
+  def extract_networks(filepath) do
+    %{"networks" => run_parser(filepath, &ArchiveParser.read_all_networks/1)}
+  rescue
+    _ -> %{"networks" => []}
+  end
+
   defp no_validity_dates, do: %{"no_validity_dates" => true}
 
   defp validity_dates(filepath) do
@@ -30,14 +42,16 @@ defmodule Transport.Validators.NeTEx.MetadataExtractor do
   end
 
   defp validity_dates_from_calendars(filepath) do
-    filepath
-    |> Transport.NeTEx.ArchiveParser.read_all_calendars()
-    |> flatten()
+    run_parser(filepath, &ArchiveParser.read_all_calendars/1)
   end
 
   defp validity_dates_from_service_calendars(filepath) do
+    run_parser(filepath, &ArchiveParser.read_all_service_calendars/1)
+  end
+
+  defp run_parser(filepath, parser) do
     filepath
-    |> Transport.NeTEx.ArchiveParser.read_all_service_calendars()
+    |> parser.()
     |> flatten()
   end
 

apps/transport/test/netex/netex_archive_parser_test.exs

@@ -279,6 +279,50 @@ defmodule Transport.NeTEx.ArchiveParserTest do
     assert [] == types
   end
 
+  test "extract Network(s)" do
+    general_frame = """
+      <PublicationDelivery xmlns="http://www.netex.org.uk/netex" version="1.04:FR1-NETEX-1.6-1.8">
+        <PublicationTimestamp>2026-02-02T15:45:04Z</PublicationTimestamp>
+        <ParticipantRef>FR1_OFFRE</ParticipantRef>
+        <dataObjects>
+          <GeneralFrame id="FR:GeneralFrame:NETEX_COMMUN:LOC" version="1.09:FR-NETEX-2.1-1.0">
+            <members>
+              <Network>
+                <Name>Réseau Urbain</Name>
+              </Network>
+              <Line>
+                <Name>Alberville - Besançon</Name>
+              </Line>
+            </members>
+          </GeneralFrame>
+        </dataObjects>
+      </PublicationDelivery>
+    """
+
+    assert ["Réseau Urbain"] == extract(&ArchiveParser.read_all_networks!/1, general_frame)
+
+    multiple_networks = """
+      <PublicationDelivery xmlns="http://www.netex.org.uk/netex" version="1.04:FR1-NETEX-1.6-1.8">
+        <PublicationTimestamp>2026-02-02T15:45:04Z</PublicationTimestamp>
+        <ParticipantRef>FR1_OFFRE</ParticipantRef>
+        <dataObjects>
+          <GeneralFrame id="FR:GeneralFrame:NETEX_COMMUN:LOC" version="1.09:FR-NETEX-2.1-1.0">
+            <members>
+              <Network>
+                <Name>Réseau Urbain</Name>
+              </Network>
+              <Network>
+                <Name>Réseau Régional</Name>
+              </Network>
+            </members>
+          </GeneralFrame>
+        </dataObjects>
+      </PublicationDelivery>
+    """
+
+    assert ["Réseau Urbain", "Réseau Régional"] == extract(&ArchiveParser.read_all_networks!/1, multiple_networks)
+  end
+
   defp extract(extractor, xml) do
     tmp_file = create_tmp_netex([{"file.xml", xml}])