extract and test inf-clojure--forms-without-newlines

Author: dpsutton

inf-clojure.el

@@ -683,6 +683,29 @@ HOST is the host the process is running on, PORT is where it's listening."
   (interactive "shost: \nnport: ")
   (inf-clojure (cons host port)))
 
+(defun inf-clojure--forms-without-newlines (str)
+  "Remove newlines between toplevel forms.
+STR is a string of contents to be evaluated.  When sending
+multiple forms to a socket repl, each newline triggers a prompt.
+So we replace all newlines between top level forms but not inside
+of forms."
+  (condition-case nil
+      (with-temp-buffer
+        (progn
+          (clojurec-mode)
+          (insert str)
+          (whitespace-cleanup)
+          (goto-char (point-min))
+          (while (not (eobp))
+            (while (looking-at "\n")
+              (delete-char 1))
+            (unless (eobp)
+              (clojure-forward-logical-sexp))
+            (unless (eobp)
+              (forward-char)))
+          (buffer-substring-no-properties (point-min) (point-max))))
+    (scan-error str)))
+
 (defun inf-clojure-eval-region (start end &optional and-go)
   "Send the current region to the inferior Clojure process.
 Sends substring between START and END.  Prefix argument AND-GO
@@ -692,22 +715,7 @@ means switch to the Clojure buffer afterwards."
          ;; newlines over a socket repl between top level forms cause
          ;; a prompt to be returned. so here we dump the region into a
          ;; temp buffer, and delete all newlines between the forms
-         (formatted (condition-case nil
-                        (with-temp-buffer
-                          (progn
-                            (clojurec-mode)
-                            (insert str)
-                            (whitespace-cleanup)
-                            (goto-char (point-min))
-                            (while (not (eobp))
-                              (while (looking-at "\n")
-                                (delete-char 1))
-                              (unless (eobp)
-                                (clojure-forward-logical-sexp))
-                              (unless (eobp)
-                               (forward-char)))
-                            (buffer-substring-no-properties (point-min) (point-max))))
-                      (scan-error str))))
+         (formatted (inf-clojure--forms-without-newlines str)))
     (inf-clojure--send-string (inf-clojure-proc) formatted))
   (when and-go (inf-clojure-switch-to-repl t)))
 

test/inf-clojure-tests.el

@@ -119,6 +119,35 @@
   (it "only removes whitespace at the end of the command - fix 152"
     (expect (inf-clojure--sanitize-command "1   5") :to-equal "1   5\n")))
 
+(describe "inf-clojure--forms-without-newlines"
+  (it "removes newlines between toplevel forms"
+    (expect (inf-clojure--forms-without-newlines
+             "(def foo 3)\n\n\n(def bar 4)")
+            :to-equal "(def foo 3)\n(def bar 4)"))
+  (it "doesn't remove newlines inside forms or strings"
+    (expect (inf-clojure--forms-without-newlines
+             "
+
+(defn foo []
+
+  :foo)
+
+
+(def thing \"this
+
+is a string\")
+
+(defn bar [])")
+            ;; note no leading newline, newlines inside defn remain,
+            ;; newlines inside string remain
+            :to-equal "(defn foo []
+
+  :foo)
+(def thing \"this
+
+is a string\")
+(defn bar [])")))
+
 
 (describe "inf-clojure--update-feature"
   (it "updates new forms correctly"