effigy/build.gradle at master · cjstehno/effigy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.8'
    }
}

subprojects {
    version = '0.4.1'
    group = 'com.stehno.effigy'

    apply plugin: 'groovy'
    apply plugin: 'codenarc'
    apply plugin: 'com.github.ben-manes.versions'

    sourceCompatibility = 8
    targetCompatibility = 8

    compileGroovy {
        groovyOptions.optimizationOptions.indy = false
    }

    configurations {
        groovyDoc
    }

    repositories {
        jcenter()
    }

    dependencies {
        compile 'org.codehaus.groovy:groovy-all:2.4.3'

        testCompile 'junit:junit:4.12'
        testCompile 'org.mockito:mockito-all:1.9.5'

        groovyDoc "org.codehaus.groovy:groovy-groovydoc:2.4.3"
        groovyDoc "org.codehaus.groovy:groovy-ant:2.4.3"
    }

    test {
        jvmArgs '-Xverify:none'
    }

    groovydoc {
        groovyClasspath = configurations.groovyDoc
    }

    codenarc {
        toolVersion = '0.23'
    }

    codenarcMain {
        ignoreFailures false
        configFile file('../config/codenarc/codenarc-main.rules')

        maxPriority1Violations 0
        maxPriority2Violations 10
        maxPriority3Violations 20
    }

    codenarcTest {
        // we won't fail the build for test inspection errors
        ignoreFailures true
        configFile file('../config/codenarc/codenarc-test.rules')
    }
}

boolean isWindows(){
    System.properties['os.name'].toLowerCase().contains('windows')
}

task guide(type:Exec,group:'Documentation', description:'Builds the user guide.'){
    inputs.dir fileTree('effigy-guide')
    outputs.dir fileTree('effigy-guide/build')

    workingDir './effigy-guide'

    if (isWindows()) {
        commandLine 'cmd', '/c', 'gaidenw.bat', 'build'

    } else {
        commandLine './gaidenw', 'build'
    }
}

task cleanGuide(type:Exec,group:'Documentation', description:'Cleans the user guide.'){
    workingDir './effigy-guide'
    if (isWindows()) {
        commandLine 'cmd', '/c', 'gaidenw.bat', 'clean'

    } else {
        commandLine './gaidenw', 'clean'
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.3'
}