Deprecate the SwiftClangModuleInfo provider.

To lessen the number of providers that rules doing Swift compilation have to deal with, required C module maps are now being propagated in `SwiftInfo` rather than their own provider (the other three fields are obsolete thanks to `CcInfo`'s compilation context).

This change retains the provider but moves it into an aspect that can be removed easily once the uses of it have been removed from Tulsi.

RELNOTES: The `SwiftClangModuleInfo` provider has been deprecated. Headers and include search paths can be obtained from `CcInfo`'s compilation context. Module maps are propagated in `SwiftInfo.transitive_modulemaps`.
PiperOrigin-RevId: 247418171

Author: allevato

swift/internal/api.bzl

@@ -75,6 +75,7 @@ _SANITIZER_FEATURE_FLAG_MAP = {
 
 def _create_swift_info(
         defines = [],
+        modulemaps = [],
         module_name = None,
         swiftdocs = [],
         swiftmodules = [],
@@ -93,6 +94,8 @@ def _create_swift_info(
 
     Args:
         defines: A list of defines that will be provided as `copts` of the target being built.
+        modulemaps: A list of module maps that should be passed to ClangImporter by any target
+            that depends on the one propagating this provider.
         module_name: A string containing the name of the Swift module. If this is `None`, the
             provider does not represent a compiled module but rather a collection of modules (this
             happens, for example, with `proto_library` targets that have no sources of their own
@@ -110,10 +113,12 @@ def _create_swift_info(
         A new `SwiftInfo` provider with the given values.
     """
     transitive_defines = []
+    transitive_modulemaps = []
     transitive_swiftdocs = []
     transitive_swiftmodules = []
     for swift_info in swift_infos:
         transitive_defines.append(swift_info.transitive_defines)
+        transitive_modulemaps.append(swift_info.transitive_modulemaps)
         transitive_swiftdocs.append(swift_info.transitive_swiftdocs)
         transitive_swiftmodules.append(swift_info.transitive_swiftmodules)
 
@@ -124,6 +129,7 @@ def _create_swift_info(
         module_name = module_name,
         swift_version = swift_version,
         transitive_defines = depset(defines, transitive = transitive_defines),
+        transitive_modulemaps = depset(modulemaps, transitive = transitive_modulemaps),
         transitive_swiftdocs = depset(swiftdocs, transitive = transitive_swiftdocs),
         transitive_swiftmodules = depset(swiftmodules, transitive = transitive_swiftmodules),
     )
@@ -443,8 +449,7 @@ def _compile(
             which affects the nature of the output files.
         defines: Symbols that should be defined by passing `-D` to the compiler.
         deps: Dependencies of the target being compiled. These targets must propagate one of the
-            following providers: `CcInfo`, `SwiftClangModuleInfo`, `SwiftInfo`, or
-            `apple_common.Objc`.
+            following providers: `CcInfo`, `SwiftInfo`, or `apple_common.Objc`.
         genfiles_dir: The Bazel `*-genfiles` directory root. If provided, its path is added to
             ClangImporter's header search paths for compatibility with Bazel's C++ and Objective-C
             rules which support inclusions of generated headers from that location.
@@ -903,8 +908,8 @@ def _swiftc_command_line_and_inputs(
           requested, which affects the nature of the output files.
       defines: Symbols that should be defined by passing `-D` to the compiler.
       deps: Dependencies of the target being compiled. These targets must
-          propagate one of the following providers: `CcInfo`,
-          `SwiftClangModuleInfo`, `SwiftInfo`, or `apple_common.Objc`.
+          propagate one of the following providers: `CcInfo`, `SwiftInfo`, or
+          `apple_common.Objc`.
       genfiles_dir: The Bazel `*-genfiles` directory root. If provided, its path
           is added to ClangImporter's header search paths for compatibility with
           Bazel's C++ and Objective-C rules which support inclusions of generated

swift/internal/attrs.bzl

@@ -14,7 +14,8 @@
 
 """Common attributes used by multiple Swift build rules."""
 
-load(":providers.bzl", "SwiftClangModuleInfo", "SwiftInfo")
+load(":legacy_swift_clang_module_info_aspect.bzl", "legacy_swift_clang_module_info_aspect")
+load(":providers.bzl", "SwiftInfo")
 
 def swift_common_rule_attrs(additional_deps_aspects = []):
     return {
@@ -29,14 +30,13 @@ binary or library, or other programs needed by it.
 """,
         ),
         "deps": attr.label_list(
-            aspects = additional_deps_aspects,
+            aspects = [legacy_swift_clang_module_info_aspect] + additional_deps_aspects,
             doc = """
 A list of targets that are dependencies of the target being built, which will be
 linked into that target. Allowed kinds of dependencies are:
 
-* `swift_c_module` (or anything propagating `SwiftClangModuleInfo`)
-* `swift_import` and `swift_library` (or anything propagating `SwiftInfo`)
-* `cc_library` (or anything propagating `CcInfo`)
+*   `swift_c_module`, `swift_import` and `swift_library` (or anything propagating `SwiftInfo`)
+*   `cc_library` (or anything propagating `CcInfo`)
 
 Additionally, on platforms that support Objective-C interop, `objc_library`
 targets (or anything propagating the `apple_common.Objc` provider) are allowed
@@ -45,7 +45,6 @@ Linux), those dependencies will be **ignored.**
 """,
             providers = [
                 [CcInfo],
-                [SwiftClangModuleInfo],
                 [SwiftInfo],
                 [apple_common.Objc],
             ],

swift/internal/compiling.bzl

@@ -22,11 +22,10 @@ load(
 )
 load(":actions.bzl", "run_toolchain_swift_action")
 load(":derived_files.bzl", "derived_files")
-load(":providers.bzl", "SwiftClangModuleInfo", "SwiftInfo")
+load(":providers.bzl", "SwiftInfo")
 load(
     ":utils.bzl",
     "collect_cc_libraries",
-    "collect_transitive",
     "get_providers",
     "objc_provider_framework_name",
 )
@@ -50,58 +49,67 @@ def collect_transitive_compile_inputs(args, deps, direct_defines = []):
     input_depsets = []
 
     # Collect all the search paths, module maps, flags, and so forth from transitive dependencies.
-    transitive_swiftmodules = collect_transitive(
-        deps,
-        SwiftInfo,
-        "transitive_swiftmodules",
-    )
-    args.add_all(transitive_swiftmodules, format_each = "-I%s", map_each = _dirname_map_fn)
-    input_depsets.append(transitive_swiftmodules)
-
-    transitive_defines = collect_transitive(
-        deps,
-        SwiftInfo,
-        "transitive_defines",
-        direct = direct_defines,
-    )
-    args.add_all(transitive_defines, format_each = "-D%s")
-
-    transitive_modulemaps = collect_transitive(
-        deps,
-        SwiftClangModuleInfo,
-        "transitive_modulemaps",
-    )
-    input_depsets.append(transitive_modulemaps)
+    transitive_cc_defines = []
+    transitive_cc_headers = []
+    transitive_cc_includes = []
+    transitive_cc_quote_includes = []
+    transitive_cc_system_includes = []
+    transitive_defines = []
+    transitive_modulemaps = []
+    transitive_swiftmodules = []
+    for dep in deps:
+        if SwiftInfo in dep:
+            swift_info = dep[SwiftInfo]
+            transitive_defines.append(swift_info.transitive_defines)
+            transitive_modulemaps.append(swift_info.transitive_modulemaps)
+            transitive_swiftmodules.append(swift_info.transitive_swiftmodules)
+        if CcInfo in dep:
+            compilation_context = dep[CcInfo].compilation_context
+            transitive_cc_defines.append(compilation_context.defines)
+            transitive_cc_headers.append(compilation_context.headers)
+            transitive_cc_includes.append(compilation_context.includes)
+            transitive_cc_quote_includes.append(compilation_context.quote_includes)
+            transitive_cc_system_includes.append(compilation_context.system_includes)
+
+    # Add import paths for the directories containing dependencies' swiftmodules.
+    all_swiftmodules = depset(transitive = transitive_swiftmodules)
+    args.add_all(all_swiftmodules, format_each = "-I%s", map_each = _dirname_map_fn)
+    input_depsets.append(all_swiftmodules)
+
+    # Pass Swift defines propagated by dependencies.
+    all_defines = depset(direct_defines, transitive = transitive_defines)
+    args.add_all(all_defines, format_each = "-D%s")
+
+    # Pass module maps from C/C++ dependencies to ClangImporter.
+    # TODO(allevato): Will `CcInfo` eventually keep these in its compilation context?
+    all_modulemaps = depset(transitive = transitive_modulemaps)
+    input_depsets.append(all_modulemaps)
+    args.add_all(all_modulemaps, before_each = "-Xcc", format_each = "-fmodule-map-file=%s")
+
+    # Add C++ headers from dependencies to the action inputs so the compiler can read them.
+    input_depsets.append(depset(transitive = transitive_cc_headers))
+
+    # Pass any C++ defines and include search paths to ClangImporter.
     args.add_all(
-        transitive_modulemaps,
+        depset(transitive = transitive_cc_defines),
         before_each = "-Xcc",
-        format_each = "-fmodule-map-file=%s",
+        format_each = "-D%s",
     )
-
-    transitive_cc_headers = collect_transitive(
-        deps,
-        SwiftClangModuleInfo,
-        "transitive_headers",
+    args.add_all(
+        depset(transitive = transitive_cc_includes),
+        before_each = "-Xcc",
+        format_each = "-I%s",
     )
-    input_depsets.append(transitive_cc_headers)
-
-    transitive_cc_compile_flags = collect_transitive(
-        deps,
-        SwiftClangModuleInfo,
-        "transitive_compile_flags",
+    args.add_all(
+        depset(transitive = transitive_cc_quote_includes),
+        before_each = "-Xcc",
+        format_each = "-iquote%s",
     )
-
-    # Handle possible spaces in these arguments correctly (for example,
-    # `-isystem foo`) by prepending `-Xcc` to each one.
-    for arg in transitive_cc_compile_flags.to_list():
-        args.add_all(arg.split(" "), before_each = "-Xcc")
-
-    transitive_cc_defines = collect_transitive(
-        deps,
-        SwiftClangModuleInfo,
-        "transitive_defines",
+    args.add_all(
+        depset(transitive = transitive_cc_system_includes),
+        before_each = "-Xcc",
+        format_each = "-isystem%s",
     )
-    args.add_all(transitive_cc_defines, before_each = "-Xcc", format_each = "-D%s")
 
     return input_depsets
 

swift/internal/legacy_swift_clang_module_info_aspect.bzl

@@ -0,0 +1,61 @@
+# Copyright 2019 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Attaches `SwiftClangModuleInfo` providers as needed to Swift targets.
+
+Tulsi depends on this provider, so we can't remove it completely until a new release has been cut.
+Moving it entirely to this aspect (which simulates the behavior that would have happened on the
+rules themselves) allows us to remove it more easily in the future.
+"""
+
+load(":providers.bzl", "SwiftClangModuleInfo", "SwiftInfo")
+
+def _legacy_swift_clang_module_info_aspect_impl(target, aspect_ctx):
+    has_interesting_provider = False
+
+    if SwiftInfo in target:
+        has_interesting_provider = True
+        swift_info = target[SwiftInfo]
+        transitive_modulemaps = swift_info.transitive_modulemaps
+    else:
+        transitive_modulemaps = depset()
+
+    if CcInfo in target:
+        has_interesting_provider = True
+        compilation_context = target[CcInfo].compilation_context
+        transitive_compile_flags = depset(
+            ["-I{}".format(path) for path in compilation_context.includes.to_list()] +
+            ["-isystem{}".format(path) for path in compilation_context.system_includes.to_list()] +
+            ["-iquote{}".format(path) for path in compilation_context.quote_includes.to_list()],
+        )
+        transitive_defines = compilation_context.defines
+        transitive_headers = compilation_context.headers
+    else:
+        transitive_compile_flags = None
+        transitive_defines = None
+        transitive_headers = None
+
+    if has_interesting_provider:
+        return [SwiftClangModuleInfo(
+            transitive_compile_flags = transitive_compile_flags,
+            transitive_defines = transitive_defines,
+            transitive_headers = transitive_headers,
+            transitive_modulemaps = transitive_modulemaps,
+        )]
+
+    return []
+
+legacy_swift_clang_module_info_aspect = aspect(
+    implementation = _legacy_swift_clang_module_info_aspect_impl,
+)