Copy matrices in triu/tril if no zero exists for the eltype (#1320)

This fixes a regression in the `triu`/`tril` implementation on v1.12 and
nightly. After this, the following works again:
```julia
julia> M = fill(ones(2,2), 3, 3)
3×3 Matrix{Matrix{Float64}}:
 [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]
 [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]
 [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]

julia> using Test: GenericArray

julia> triu(GenericArray(M),1)
3×3 GenericArray{Matrix{Float64}, 2}:
 [0.0 0.0; 0.0 0.0]  [1.0 1.0; 1.0 1.0]  [1.0 1.0; 1.0 1.0]
 [0.0 0.0; 0.0 0.0]  [0.0 0.0; 0.0 0.0]  [1.0 1.0; 1.0 1.0]
 [0.0 0.0; 0.0 0.0]  [0.0 0.0; 0.0 0.0]  [0.0 0.0; 0.0 0.0]
```

Author: jishnub

src/generic.jl

@@ -446,7 +446,8 @@ julia> triu(a,-3)
  1.0  1.0  1.0  1.0
 ```
 """
-function triu(M::AbstractMatrix, k::Integer = 0)
+triu(M::AbstractMatrix, k::Integer = 0) = _triu(M, Val(haszero(eltype(M))), k)
+function _triu(M::AbstractMatrix, ::Val{true}, k::Integer)
     d = similar(M)
     A = triu!(d,k)
     if iszero(k)
@@ -459,6 +460,14 @@ function triu(M::AbstractMatrix, k::Integer = 0)
     end
     return A
 end
+function _triu(M::AbstractMatrix, ::Val{false}, k::Integer)
+    d = similar(M)
+    # since the zero would need to be evaluated from the elements,
+    # we copy the array to avoid undefined references in triu!
+    copy!(d, M)
+    A = triu!(d,k)
+    return A
+end
 
 """
     tril(M, k::Integer = 0)
@@ -489,7 +498,8 @@ julia> tril(a,-3)
  1.0  0.0  0.0  0.0
 ```
 """
-function tril(M::AbstractMatrix,k::Integer=0)
+tril(M::AbstractMatrix,k::Integer=0) = _tril(M, Val(haszero(eltype(M))), k)
+function _tril(M::AbstractMatrix, ::Val{true}, k::Integer)
     d = similar(M)
     A = tril!(d,k)
     if iszero(k)
@@ -502,6 +512,14 @@ function tril(M::AbstractMatrix,k::Integer=0)
     end
     return A
 end
+function _tril(M::AbstractMatrix, ::Val{false}, k::Integer)
+    d = similar(M)
+    # since the zero would need to be evaluated from the elements,
+    # we copy the array to avoid undefined references in tril!
+    copy!(d, M)
+    A = tril!(d,k)
+    return A
+end
 
 """
     triu!(M)

test/dense.jl

@@ -1374,4 +1374,14 @@ end
     @test !any(LinearAlgebra.getstructure(A))
 end
 
+@testset "triu/tril for block matrices" begin
+    O = ones(2,2)
+    Z = zero(O)
+    M = fill(O, 3, 3)
+    res = fill(Z, size(M))
+    res[1,2] = res[1,3] = res[2,3] = O
+    @test triu(GenericArray(M),1) == res
+    @test tril(GenericArray(M),-1) == res'
+end
+
 end # module TestDense