Forward diagview for adjoint/transpose to parent (#1373)

After this,
```julia
julia> B = reshape([1:9;], 3, 3)
3×3 Matrix{Int64}:
 1  4  7
 2  5  8
 3  6  9

julia> diagview(B', 1)
2-element view(::Vector{Int64}, 2:4:6) with eltype Int64:
 2
 6
```
The view directly indexes into the parent, and the `adjoint` layer is
removed. This also makes the view linearly indexed.

Author: jishnub

src/adjtrans.jl

@@ -536,3 +536,23 @@ conj(A::Adjoint) = transpose(A.parent)
 function Base.replace_in_print_matrix(A::AdjOrTrans,i::Integer,j::Integer,s::AbstractString)
     Base.replace_in_print_matrix(parent(A), j, i, s)
 end
+
+# Special adjoint/transpose methods for Adjoint/Transpose that have been reshaped as a vector
+# these are used in transposing banded matrices by forwarding the operation to the bands
+"""
+    _vectranspose(A::AbstractVector)::AbstractVector
+
+Compute `vec(transpose(A))`, but avoid an allocating reshape if possible
+"""
+_vectranspose(A::AbstractVector) = vec(transpose(A))
+_vectranspose(A::Base.ReshapedArray{<:Any,1,<:TransposeAbsVec}) = transpose(parent(A))
+"""
+    _vecadjoint(A::AbstractVector)::AbstractVector
+
+Compute `vec(adjoint(A))`, but avoid an allocating reshape if possible
+"""
+_vecadjoint(A::AbstractVector) = vec(adjoint(A))
+_vecadjoint(A::Base.ReshapedArray{<:Any,1,<:AdjointAbsVec}) = adjoint(parent(A))
+
+diagview(A::Transpose, k::Integer = 0) = _vectranspose(diagview(parent(A), -k))
+diagview(A::Adjoint, k::Integer = 0) = _vecadjoint(diagview(parent(A), -k))

test/adjtrans.jl

@@ -749,4 +749,15 @@ end
     end
 end
 
+@testset "diagview" begin
+    for A in (rand(4, 4), rand(ComplexF64,4,4),
+                fill([1 2; 3 4], 4, 4))
+        for k in -3:3
+            @test diagview(A', k) == diag(A', k)
+            @test diagview(transpose(A), k) == diag(transpose(A), k)
+        end
+        @test IndexStyle(diagview(A')) == IndexLinear()
+    end
+end
+
 end # module TestAdjointTranspose