chore(ci): add final_status property on junit XML [APMSP-2610] (#178)

### What does this PR do?

Add a `<property name="dd_tags[test.final_status]" value="pass" />` on
every test case reported through junit

Also updated system-tests SHA, the used one was very old, and the
support for `final_status` in system-tests has been introduced recently

### Motivation

Some repositories intentionally use mechanisms that ignore test failures
(there are valid reasons to still execute those tests behind the
scenes).

In these cases, the reported test status cannot be relied upon by Test
Optimization to monitor repository health or trigger team notifications.

To ensure a consistent and unified approach, we will instead use
final_status — the property specifically designed and used by the Test
Optimization integration for this purpose.

# how to test it ? 

Now more `N/A` on the last commit on this
[query](https://app.datadoghq.com/ci/test/runs?query=test_level%3Atest%20%40git.repository.id_v2%3A%2A%2Fdd-trace-rs%20%40git.branch%3Acbeauchesne%2Ffinal_status%20%40git.commit.sha%3A01dfca97ce3335fb9f346225888329ef3b1f68d8&agg_m=%40test.full_name&agg_m_source=base&agg_q=%40test.final_status&agg_q_source=base&agg_t=cardinality&currentTab=overview&eventStack=&fromUser=false&index=citest&sort_m=count&sort_m_source=base&sort_t=count&top_n=10&top_o=top&viz=timeseries&x_missing=false&start=1772906562779&end=1773165762779&paused=false)

# Additional Notes

I'm using the not-that-ideal XSLT here as this change, because it must
be done over [17+
repos](https://datadoghq.atlassian.net/browse/APMSP-2610), and it's a
workaround until this gets integrated into a better place, such as
datadog-ci or the backend.

We're trying to work with the team on this, please have a look on this
[RFC](https://docs.google.com/document/d/1OaX_h09fCXWmK_1ADrwvilt8Yt5h4WjC7UUAdS3Y3uw/edit?pli=1&tab=t.0#heading=h.tfy5viz7rz2)
for more context.

Author: cbeauchesne

.github/workflows/add_final_status.xsl

@@ -0,0 +1,50 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+  <!-- Identity transform: copy everything as-is by default -->
+  <xsl:template match="@*|node()">
+    <xsl:copy>
+      <xsl:apply-templates select="@*|node()"/>
+    </xsl:copy>
+  </xsl:template>
+
+  <!-- For testcase elements missing dd_tags[test.final_status] inside their properties block -->
+  <xsl:template match="testcase[not(properties/property[@name='dd_tags[test.final_status]'])]">
+    <xsl:copy>
+      <xsl:apply-templates select="@*"/>
+      <xsl:variable name="status">
+        <xsl:choose>
+          <xsl:when test="failure or error">fail</xsl:when>
+          <xsl:when test="skipped">skip</xsl:when>
+          <xsl:otherwise>pass</xsl:otherwise>
+        </xsl:choose>
+      </xsl:variable>
+      <xsl:choose>
+        <xsl:when test="properties">
+          <!-- Inject into existing properties block, preserving child order -->
+          <xsl:for-each select="node()">
+            <xsl:choose>
+              <xsl:when test="self::properties">
+                <properties>
+                  <xsl:apply-templates select="@*|node()"/>
+                  <property name="dd_tags[test.final_status]" value="{$status}"/>
+                </properties>
+              </xsl:when>
+              <xsl:otherwise>
+                <xsl:apply-templates select="."/>
+              </xsl:otherwise>
+            </xsl:choose>
+          </xsl:for-each>
+        </xsl:when>
+        <xsl:otherwise>
+          <!-- No properties block: create one before other children -->
+          <properties>
+            <property name="dd_tags[test.final_status]" value="{$status}"/>
+          </properties>
+          <xsl:apply-templates select="node()"/>
+        </xsl:otherwise>
+      </xsl:choose>
+    </xsl:copy>
+  </xsl:template>
+
+</xsl:stylesheet>

.github/workflows/test.yaml

@@ -75,6 +75,16 @@ jobs:
           report_paths: "target/nextest/ci/junit.xml"
           check_name: "[${{ matrix.platform }}:${{ matrix.rust_version }}] test report"
           include_passed: true
+      - name: Add final_status property
+        if: success() || failure()
+        shell: bash
+        run: |
+          which xsltproc || sudo apt-get install -y xsltproc
+          xml_file="target/nextest/ci/junit.xml"
+          echo "Fixing $xml_file"
+          tmp_file="$(mktemp)"
+          xsltproc --output "$tmp_file" ".github/workflows/add_final_status.xsl" "$xml_file"
+          mv "$tmp_file" "$xml_file"
       - name: Upload test results to Datadog
         if: success() || failure()
         shell: bash
@@ -165,13 +175,13 @@ jobs:
   parametric:
     needs:
       - build-artifacts
-    uses: DataDog/system-tests/.github/workflows/run-parametric.yml@bafc8bc606d76170d98ce3cdb13c75a1ea9cf924  # main
+    uses: DataDog/system-tests/.github/workflows/run-parametric.yml@93283b322c59ecf7267c28c06648d341be75eded  # main
     secrets:
       TEST_OPTIMIZATION_API_KEY: ${{ secrets.DATADOG_API_KEY }}
     with:
       library: rust
       binaries_artifact: system_tests_binaries
       job_count: 2
       job_matrix: '[1,2]'
-      ref: 8a65f66d74ca77f34e7e5a2f737e963ce9cec563 # main
+      ref: 93283b322c59ecf7267c28c06648d341be75eded # main
       push_to_test_optimization: true